Potrzebuje szybo skrypt na random tp 1.16.5

Pokaż co przejrzałeś i ci niby nie działa

Wszystkie posty z randomtp i nic nie działa bo nikt nigdy nie kończył rozmowy z kodem w całości tylko poprawkami , proszę abyś dal mi tu link , post w którym będę miał losowe tp na gąbce z kamiennym guzikiem i żebym mógł przypisać do niego komendę żeby gracze nie mogli tego robić i se ustawiać tp gdzie chcą  

options: xMin: 1000 xMax: 200 zMin: 400 zMax: 800 yMin: 70 yMax: 90 world: world aliases: blocktpr = 1, 2, 3, 4, 12, 13, 49, 7, 8, 5, 18, 172, 24, 9 variables: {godteleport.%player%} = false on rightclick on stone button: block behind target block is sponge: set {_targetx} to a random integer between {@xMin} and {@xMax} set {_targetz} to a random integer between {@zMin} and {@zMax} set {_targety} to 0 set {_random.pos} to location at {_targetx}, {_targety}, {_targetz} biome at {_random.pos} is ocean or river or deep ocean: send "&8» &4Blad! &3Lokacja znajduje sie na oceanie!" else: loop blocks above the block at location of {_random.pos}: if block at location of loop-block is blocktpr: if block above the block at location of loop-block is air or water: if block 1 above the block at location of loop-block is air: if block 2 above the block at location of loop-block is air: set {_pos} to block above the block at location of loop-block apply speed 2 to the player for 4 seconds apply regeneration 10 to the player for 5 seconds apply invisibility 10 to the player for 8 seconds set {godteleport.%player%} to true send "&8» &7Przeteleportowano na kordynaty &3x: %{_targetx}% z: %{_targetz}%&7!" to player add 64 cooked porkchop to player teleport player to {_pos} wait 10 seconds set {godteleport.%player%} to false stop tu koelga napisal ale on nie tepa tylko pisze na czacie ze tp w losowe i dziala na jeden guzik 

ale taki kod nie ma nawet prawa działać, gdzie tu jakieś entery, wcięcia

options:
	x-min: -3000
	x-max: 3000
	z-min: -3000
	z-max: 3000
	world: "world"
command /randomteleport:
	aliases: rtp
	permission: rtp.cmd.rtp
	trigger:
		set {_x} to random integer between {@x-min} and {@x-max}
		set {_z} to random integer between {@z-min} and {@z-max}
		set {_loc} to location at ({_x}, 256, {_z}) in world {@world}
		while "%biome at {_loc}%" contains "ocean":
			set {_x} to random integer between {@x-min} and {@x-max}
			set {_z} to random integer between {@z-min} and {@z-max}
			set {_loc} to location at ({_x}, 256, {_z}) in world {@world}
		wait a second
		teleport player to block above highest solid block at {_loc}
		wait 5 ticks
		play ender signal above highest solid block at {_loc} to player
		play sound "ENTITY_ENDERMAN_TELEPORT" with volume 0.5 to player
		if highest solid block at {_loc} is water:
			spawn boat at highest solid block at {_loc}
			set spawned boat's passenger to player
		send "&7Zostałeś teleportowany w losowe miejsce na mapie."
command /setrtp:
	permission: rtp.cmd.setrtp
	trigger:
		if {rtp::setrtp::%player%} is not set:
			set {rtp::setrtp::%player%} to true
			send "&7Kliknij przycisk, który ma działać jako teleport."
		else:
			clear {rtp::setrtp::%player%}
			send "&cAnulowano ustawianie przycisku teleportujacego."
on rightclick:
	if event-block is any button:
		if {rtp::setrtp::%player%} is set:
			cancel event
			if {rtp::buttons::*} contains event-location:
				send "&cTen przycisk jest już ustawiony jako teleport."
			else:
				add event-location to {rtp::buttons::*}
				send "&aUstawiono kliknięty przycisk jako teleport."
		else:
			if {rtp::buttons::*} contains event-location:
				if player has permission "rtp.button.use":
					set {_x} to random integer between {@x-min} and {@x-max}
					set {_z} to random integer between {@z-min} and {@z-max}
					set {_loc} to location at ({_x}, 256, {_z}) in world {@world}
					while "%biome at {_loc}%" contains "ocean":
						set {_x} to random integer between {@x-min} and {@x-max}
						set {_z} to random integer between {@z-min} and {@z-max}
						set {_loc} to location at ({_x}, 256, {_z}) in world {@world}
					wait a second
					teleport player to block above highest solid block at {_loc}
					wait 5 ticks
					play ender signal above highest solid block at {_loc} to player
					play sound "ENTITY_ENDERMAN_TELEPORT" with volume 0.5 to player
					if highest solid block at {_loc} is water:
						spawn boat at highest solid block at {_loc}
						set spawned boat's passenger to player
					send "&7Zostałeś teleportowany w losowe miejsce na mapie."

komendą /setrtp przechodzisz do trybu ustawiania przycisku. Aby go ustawić kliknij na niego prawym przyciskiem myszy.
Komenda /rtp działa jak przycisk.

Jeśli gracz trafi na wodę to skrypt teleportuje go do łódki. Jeśli chcesz to usunąć to usuń:

if highest solid block at {_loc} is water:
	spawn boat at highest solid block at {_loc}
	set spawned boat's passenger to player

Ten temat został przeniesiony.