Kity

options:
	file: "../../Kits/config.yml"
on script load:
	if yaml value "created" from {@file} is not set:
		set yaml value "created" from {@file} to true
		set yaml value "kits.pierwszy.displayItem" from {@file} to "diamond"
		set yaml value "kits.pierwszy.displayItemName" from {@file} to "&8Moj pierwszy &r&lkit"
		set yaml value "kits.pierwszy.permission" from {@file} to "<none>"
		set yaml value "kits.pierwszy.time" from {@file} to "5 hour"
		add "64 diamonds" to yaml list "kits.pierwszy.items" from {@file}
		add "16 gold ingot" to yaml list "kits.pierwszy.items" from {@file}
	#Sprawdzanie...
	send "Start check config..." to console 
	set {_x} to now
	set {_kits::*} to yaml nodes "kits" from {@file}
	loop {_kits::*}:
		set {_displayItem} to yaml value "kits.%loop-value%.displayItem" from {@file}
		set {_displayItem} to {_displayItem} parsed as item type
		set {_time} to yaml value "kits.%loop-value%.time" from {@file}
		set {_time} to {_time} parsed as timespan
		if {_displayItem} is not item type:
			send "Config error: kits.%loop-value%.displayItem is not item type." to console 
		if {_time} is not time span:
			send "Config error: kits.%loop-value%.time is not time span." to console 
			send "Eg. 5 second, 5 hour, 25 minutes, 7 days" to console 
		set {_items::*} to yaml list "kits.%loop-value%.items" from {@file}
		loop {_items::*}:
			set {_item} to "%loop-value-2%" parsed as item type
			if {_item} is not item type:
				send "Config error: kits.%loop-value-1%.%loop-value-2% is not item type." to console 
	send "Check config done. %difference between {_x} and now%" to console 
command /kit [<text>] [<text>]:
	trigger:
		if arg 1 is not set:
			set {_kits::*} to yaml nodes "kits" from {@file}
			set {_rows} to ceil(("%size of {_kits::*}%" parsed as integer + 1) / 9)
			open chest with {_rows} rows named "&6Zestawy" to player
			wait 2 tick
			set {_kits::*} to yaml nodes "kits" from {@file}
			loop {_kits::*}:
				set {_item} to yaml value "kits.%loop-value%.displayItem" from {@file}
				set {_item} to "%{_item}%" parsed as item type
				set {_name} to yaml value "kits.%loop-value%.displayItemName" from {@file} 
				set {_permission} to yaml value "kits.%loop-value%.permission" from {@file}
				set {_items::*} to yaml list "kits.%loop-value%.items" from {@file}
				set {_items} to "%{_items::*}%"
				replace all " and" with "," in {_items}
				replace all ", " with "||&3 " in {_items}
				set {_access} to "&aTak"
				if "%{_permission}%" is not "<none>":
					if player doesn't have permission "%{_permission}%":
						set {_access} to "&4Nie"
				if {kits::%player%::%loop-value%} is not set:
					set {kits::%player%::%loop-value%} to "&fTeraz"
				if {kits::%player%::%loop-value%} is smaller than or equal to now:
					set {kits::%player%::%loop-value%} to "&fTeraz"
				set player's current inventory's slot loop-index parsed as integer - 1 to {_item} named coloured "%{_name}%" with lore "&c* &aDostepny: %{_access}%||&c* Gotowy:||  &f%{kits::%player%::%loop-value%}%||&6Itemy:||&3 %{_items}%"
on inventory click:
	if "%inventory name of player's current inventory%" is "&6Zestawy":
		if slot is smaller than 0:
			stop
		cancel event
		if player's current inventory's slot slot is not air:
			set {_displayItem} to player's current inventory's slot slot
			set {_kits::*} to yaml nodes "kits" from {@file}
			set {_lp} to {_kits::%slot + 1%}
			set {_lore::*} to uncoloured lore of player's current inventory's slot slot split by "||"
			replace all "* Dostepny: " with "" in {_lore::1}
			replace all " " with "" in {_lore::3}
			if {_lore::1} is "Nie":
				set {_permission} to yaml value "kits.%{_lp}%.permission" from {@file}
				send "&c* Nie posiadasz permisii: &8(&7%{_permission}%&8)"
				stop
			if {_lore::3} is not "Teraz":
				if size of {kits::%player%::%{_lp}%::*} is not larger than 0:
					stop
				close player's inventory
				wait 2 tick
				set {_rows} to ceil("%size of {kits::%player%::%{_lp}%::*}%" parsed as integer / 9)
				set {_name} to yaml value "kits.%{_lp}%.displayItemName" from {@file}
				open chest with {_rows} rows named "%coloured {_name}%" to player
				wait 2 tick
				loop {kits::%player%::%{_lp}%::*}:
					set player's current inventory's slot loop-index parsed as integer - 1 to loop-value
				send "Otworzone ze schowka."
				set {kits::%player%} to {_lp}
				stop
			if {_lp} is not set:
				stop
			close player's inventory
			wait 2 tick
			set {_items::*} to yaml list "kits.%{_lp}%.items" from {@file}
			set {_rows} to ceil("%size of {_items::*}%" parsed as integer / 9)
			set {_name} to yaml value "kits.%{_lp}%.displayItemName" from {@file}
			open chest with {_rows} rows named "%{_name}%" to player
			loop {_items::*}:
				set {_item} to "%loop-value%" parsed as item type
				set player's current inventory's slot loop-index parsed as integer - 1 to {_item}
			set {kits::%player%::%{_lp}%} to now
			set {_time} to yaml value "kits.%{_lp}%.time" from {@file}
			set {_time} to {_time} parsed as time span
			add {_time} to {kits::%player%::%{_lp}%}
			set {kits::%player%} to {_lp}
on inventory close:
	if {kits::%player%} is not set:
		stop
	set {_x} to {kits::%player%}
	if {_x} is set:
		clear {kits::%player%::%{_x}%::*}
		set {_i} to 0
		loop 54 times:
			if "%player's current inventory's slot {_i}%" is "<none>":
				exit loop
			if "%player's current inventory's slot {_i}%" is not "air":
				add player's current inventory's slot {_i} to {kits::%player%::%{_x}%::*}
			add 1 to {_i}
	clear {kits::%player%}