Jak zmienic minutes w minuty

Godzinę temu, Bartek123344 napisał:

https://imgur.com/a/o5KcH6q

 

Można napisać na to funkcję ktróra wygląda tak:

function TimeSpan(time: text) :: text:
	set {_t} to "%{_time}%"
	replace all " minutes" and " minute" with "m" in {_t}
	replace all " days" and " day" with "d" in {_t}
	replace all " hours" and " hour" with "h" in {_t}
	replace all " minutes" and " minute" with "m" in {_t}
	replace all " seconds" and " second" with "s" in {_t}
	return {_t}

Możesz jej użyć w taki sposób:

command /sendtimespan:
	trigger:
		set {_X} to 10 seconds
		set {_FormattedX} to TimeSpan("%{_X}%")
		#{_FormattedX} = 10s

Pozdrawiam.
 

command /shout [<text>]:
	permission: shout.*
	permission message: &cBrak permisji!
	cooldown: 5 minutes
	cooldown message: &cPoczekaj &e%remaining time%&c aby znowu napisac na shout
	trigger:
		if arg 1 is not set:
			send "&cPodaj wiadomosc!"
			cancel the cooldown
		else:
			send "" to all players
			send " &8[&a&lSHOUT&8] &f%player% <##ffb54d>»&a %arg 1%" to all players
			send "" to all players

O to moj kod. Jak mam zmienic aby dzialalo :?

Spróbuj w cooldown message ustawić:

%TimeSpan(remaining time)%

Natomiast nie jestem pewien czy to zadziała, z tego co kojarzę, kiedyś był z tym problem. 

Jeśli to nie będzie działać, musisz zaimplementować własny mechanizm cooldownu. 

W dniu 11.09.2024 o 20:50, CoFFeIN04 napisał:

Spróbuj w cooldown message ustawić:

%TimeSpan(remaining time)%

Natomiast nie jestem pewien czy to zadziała, z tego co kojarzę, kiedyś był z tym problem. 

Jeśli to nie będzie działać, musisz zaimplementować własny mechanizm cooldownu. 

To prawda, kiedyś faktycznie był z tym problem, ale 'cooldown message' poprawnie parse'uje wszystkie wyrażenia (a więc również zmienne), choć trzeba uważać na zagnieżdżanie tekstu w wyrażeniach, bo powoduje to zwrócenie błędu. Testowy kod poniżej.

local function formatTimespan(t: string) :: string:
	loop ("day", "hour", "minute", "second"):
		replace all (loop-value + "s" and loop-value) with (first character of loop-value) in {_t}
	return {_t}

command /test:
	cooldown: 10 seconds
	cooldown message: test: %formatTimespan(concat(remaining time))%
	trigger:
		send "Test."

Aby ominąć problem z cudzysłowami, o którym wspomniałem, skorzystałem z funkcji 'concat'.

Pozdrawiam.