Pin

nie lepiej włączyć whitelist i dopisać do niej osoby które moga wejść?

Nie, potrzebuję takiego skriptu.

skrypt jest o wiele bardziej skomplikowany niż się wydaje na 1 rzut oka
nie widzę sensu używania takiego skryptu przy możliwości ustawienia whitelist
lub wgrania AuthMe z zablokowaną opcja zakładania kont (tylko op lub konsola mogą wtedy założyć konto graczowi)

3 godziny temu, Saanjuk napisał:

nie widzę sensu używania takiego skryptu przy możliwości ustawienia whitelist

Szczerze... Ja też XD Po prostu go potrzebuje.

3 godziny temu, Saanjuk napisał:

skrypt jest o wiele bardziej skomplikowany niż się wydaje na 1 rzut oka

Potrafisz go zrobić?

To jak chcesz coś za darmo, to masz tu jakiś skrypt z podobnym działaniem, wystarczy tylko go lekko przerobić, pod swoje wymagania.

https://forums.skunity.com/resources/pin-login.875/

Dzięki ale potrzebował bym coś bardziej pod moje oczekiwania. Ten skript nie spełnia moich wymagań a średnio potrafię go przerobić  

options:
    gui_name: "&6Wprowadz pin"
command /dodaj [<offlineplayer>] [<number>]:
    permission: *
    trigger:
        if arg 2 is not set:
            send "correct usage..."
            stop
        set {pin::%arg 1%} to arg 2
        send "ustawiono"
command /usun [<offlineplayer>] [<number>]:
    permission: *
    trigger:
        if arg 2 is not set:
            send "correct usage..."
            stop
        clear {pin::%arg 1%}
        send "usunieto"

function getPinGui() :: inventory:
    set {_inv} to chest inventory with 5 rows named {@gui_name}
    set {_inv}'s slot (all integers between 0 to (9*5)-1) to gray glass pane named " "
    set {_s} to 12
    set {_i} to 1
    loop 3 times:
        loop 3 times:
            set {_inv}'s slot {_s} to {_i} of paper named "&e%{_i}%"
            add 1 to {_s} and {_i}
        add (9-3) to {_s}
    return {_inv}
on inventory click:
    if name of clicked inventory is not {@gui_name}:
        stop
    cancel event
    if (uncolored name of clicked slot) parsed as number is not number:
        stop
    set {currentPin::%player%} to "%{currentPin::%player%}%%(uncolored name of clicked slot)%"
    if length of {currentPin::%player%} is not 3:
        stop
    if {currentPin::%player%} is not "%{pin::%player%}%":
        send "&cPodano zly pin"
        clear {logPin::%player%} and {currentPin::%player%}
        close player's inventory
        kick player due to "&cPodano zly pin"
        stop
    send "&aPodano prawidlowy pin"
    clear {logPin::%player%} and {currentPin::%player%}
    close player's inventory
on inventory close:
    if name of player's inventory is not {@gui_name}:
        stop
    if {logPin::%player%} is not true:
        stop
    open getPinGui() to player
    send "&aWprowadz pin"
on join:
    wait second
    open getPinGui() to player
    set {currentPin::%player%} to ""
    set {logPin::%player%} to true

Dzięki wielkie @xAxee

Wszystko działa!

Do zamknięcia

Zlecenie zostało wykonane.