[szukam] Skrypt na kody twórcy

Ten temat został przeniesiony.

3 minuty temu, hbrt napisał:

Witam, chciałbym, aby ktoś miły napisał mi skrypt.
Miałby on na celu sprawdzanie ilości użyć danego kodu.

Permissie:
 - kod.ilosc (dla administracji komenda: /kodilość <kod twórcy>)
 - kod.use (dla graczy komenda: /kod <kod twórcy>)

Kody można byłoby np. dodawać/usuwać w pliku yml.

Jeżeli kod twórcy nie zgadza się z żadnym z kodów zapisanych w yml, graczowi pokazałaby się informacja "&c&lNie poprawny kod twórcy"
Cooldown: 1w (1 tydzień)

Dodatkowo pod komendą /top-kody na chacie pokazywałoby się top 10 najczęściej używanych kodów + liczba użyć każdego z nich.

 

Z góry wielkie dzięki!

 

PS gdyby ktoś chciał, to mógłby też dodać permissię kod.edit oraz komendy: /kod del <kod twórcy> i /kod add <kod twórcy>, które od razu aktualizowałyby kody w yml.

Czy musi być to w yml? To jest tylko utrudnienie, łatwiej byłoby zrobić to w zmiennej.

Teraz, Glitchtrap napisał:

Czy musi być to w yml? To jest tylko utrudnienie, łatwiej byłoby zrobić to w zmiennej.

Oczywiście, że nie, to był tylko przykład.
Można też to zrobić w kodzie (zmiennej) tak, jak napisałeś.

Teraz, hbrt napisał:

Oczywiście, że nie, to był tylko przykład.
Można też to zrobić w kodzie (zmiennej) tak, jak napisałeś.

on load:
	createCooldown("kod", 7 day)

command /kod <text> [<text>]:
	usage: &c&lPodaj kod tworcy!
	trigger:
		if arg-2 is not set:
			if getCooldown(player, "kod"):
				if {kod::%arg-1%} is not set:
					send "&c&lNiepoprawny kod tworcy"
					stop
				add 1 to {kod::%arg-1%}
				send "&a&lPoprawnie uzyto kodu!"
				setCooldown(player, "kod")
				stop
			set {_czas} to getCooldownText%player, "kod")
			send "&c&lMusisz odczekac jeszcze %{_czas}%"
			stop
		if player has permission "kod.edit":
			if arg-1 is "del":
				clear {kod::%arg-2%}
				stop
			if arg-1 is "add":
				set {kod::%arg-2%} to 0

command /top-kody [<text>]:
	trigger:
		send createTop("kod", 10, "&7[I]. &b[P]&7: &3[V]")
				

Nie wiedziałem co ma robić /kod-ilosc, więc nie dodałem.
Wymaga: AxCooldown i pyraTop Reborn

Patrząc na to, co się wyświetla, myślę, że pobrany przeze mnie wcześniej skrypt AxJobs gryzie się z pyraTOP REBORN.
Chciałem zapytać, czy masz jakiś pomysł, aby pozbyć się tego błędu bez jakichś większych zmian?

Edit:
Co do komendy /kod-ilosc, to chodziło mi o to, aby była możliwość sprawdzenia ilości użyć danego kodu.

options:
    cooldown : 5

command /kod <text> [<text>]:
    usage: &cPoprawne użycie: /kod [dodaj/usun/ilosc] <kod> 
    trigger:
        if arg-1 is "dodaj":
            if arg-2 is set:
                if {kody::*} does not contain arg-2:
                    add arg-2 to {kody::*}
                    send "&aDodałeś nowy kod ""&9%arg-1%""&a!"
                else:
                    send "&cTaki kod już istnieje!"
        else if arg-1 is "usun":
            if arg-2 is set:
                if {kody::*} contains arg-2:
                    remove arg-2 from {kody::*}
                    send "&aUsunąłeś kod ""&9%arg-1%""&a!"
                else:
                    send "&cTaki kod nie istnieje!"
        else if arg-1 is "ilosc":
            if arg-2 is set:
                loop {kody::*}:
                    if {kody::%loop-value%::uzycia} is set:
                        send "&9%loop-value%:&a %{kody::%loop-value%::uzycia}%" to executor 
        else:
            if {kody::*} contains arg-1:
                if {kody::%arg-1%::%executor%} is not set:
                    send "&aPoprawnie użyłeś kodu ""&9%arg-1%""&a!"
                    add 1 to {kody::%arg-1%::uzycia}
                    set {kody::%arg-1%::%executor%} to now
                else:
                    if difference between {kody::%arg-1%::%executor%} and now is less than {@cooldown} seconds:
                        send "&cJuż użyłeś tego kodu! Spróbuj ponownie później!" to executor
                    else:
                        delete {kody::%arg-1%::%executor%}
                        make executor execute command "/kod %arg-1%"
            else:
                send "&cTaki kod nie istnieje!"

Nie wymaga addonów
edit: zapomniałem dodać permisji, mam nadzieję że sam sobie z tym już poradzisz :d

Dziękuję @Mushkrem@Glitchtrap dziękuję bardzo, dzięki wam sobie poradziłem, a oto kod:
 

options:
	cooldown : 7

command /koddodaj <text>:
	usage: &c&lPoprawne użycie: /koddodaj <kod>
	trigger:
		if player has permission "kod.edit" or "*":
			if arg-1 is set:
				if {kody::*} does not contain arg-1:
					add arg-1 to {kody::*}
					send "&a&lDodałeś nowy kod ""&r&9%arg-1%&r&a""!"
				else:
					send "&c&lTaki kod już istnieje!"
		else:
			send "&cNie masz uprawnień"

command /kodusun <text>:
	usage: &c&lPoprawne użycie: /kodusun <kod>
	trigger:
		if player has permission "kod.edit" or "*":
			if arg-1 is set:
				if {kody::*} contains arg-1:
					remove arg-1 from {kody::*}
					send "&a&lUsunąłeś kod ""&r&9%arg-1%&r&a""!"
				else:
					send "&cTaki kod nie istnieje!"
		else:
			send "&cNie masz uprawnień"

command /kodilosc <text>:
	usage: &cPoprawne użycie: /kodilosc <kod>
	trigger:
		if player has permission "kod.ilosc" or "*":
			if arg-1 is set:
				loop {kody::*}:
					if {kody::%loop-value%::uzycia} is set:
						send "&9%loop-value%:&a %{kody::%loop-value%::uzycia}%" to executor 

command /kod <text>:
	usage: &cPoprawne użycie: /kod <kod>
	trigger:
		if {kody::*} contains arg-1:
			if {kody::%arg-1%::%executor%} is not set:
				send "&aPoprawnie użyłeś kodu ""&r&9%arg-1%&r&a""!"
				add 1 to {kody::%arg-1%::uzycia}
				set {kody::%arg-1%::%executor%} to now
			else:
				if difference between {kody::%arg-1%::%executor%} and now is less than {@cooldown} days:
					send "&cJuż użyłeś tego kodu! Spróbuj ponownie później!" to executor
				else:
					delete {kody::%arg-1%::%executor%}
					make executor execute command "/kod %arg-1%"
		else:
			send "&cTaki kod nie istnieje!"

command /kodtop:
	trigger:
		if player has permission "kody.top" or "*":
			loop {kody::*}:
				if {kody::%loop-value%::uzycia} is not set:
					set {kody::%loop-value%::uzycia} to 0
				add "%{kody::%loop-value%::uzycia}% - %loop-value%" to {_lista::*}
			set {_listasort::*} to alphabetically sorted {_lista::*}
			loop {_lista::*}:
				set {_reversed::%loop-index%} to last element of {_listasort::*}
				remove {_reversed::%loop-index%} from {_listasort::*}
			loop {_reversed::*}:
				send "&6##%loop-index% &7- &a%loop-value%" to executor
		else:
			send "&cBrak dostępu!"

Dziękuję @Mushkrem i @Glitchtrap za pomoc!

Oj, szkoda że wcześniej zapomniałem o tej topce, przez to powstało malutkie ograniczenie 

command /kodtop:
    trigger:
        loop {kody::*}:
            if {kody::%loop-value%::uzycia} is not set:
                set {kody::%loop-value%::uzycia} to 0
            add "%{kody::%loop-value%::uzycia}% - %loop-value%" to {_lista::*}
        set {_listasort::*} to alphabetically sorted {_lista::*}
        loop {_lista::*}:
            set {_reversed::%loop-index%} to last element of {_listasort::*}
            remove {_reversed::%loop-index%} from {_listasort::*}
        loop {_reversed::*}:
            send "##%loop-index% - %loop-value%" to executor

To powinno działać, ale tak jak mówiłem, nie możesz zmienić kolejności - tj. #1 <ilość użyć> <kod> przez ten średnio napisany wyżej kod  

Problem został rozwiązany.