Skrypt na pisanie na chacie

Godzinę temu, DeepesT napisał:

Witam serdecznie to znowu ja tak ja  czy byłby ktos tak miły i napisał dla mnie skrypt na pisanie na chacie od ilości wykopanego stone wraz z licznikiem np : aby pisac na chacie potrzebujesz miec wykopane 200 kamienia (ilość wykopanego kamienia/200) zablokowane komendy typu /msg ,/r ,/m dopuki gdy gracz nie wykopie kamienia a gdy wykopie 200 kamienia to pisze mu juz mozesz pisac na chacie a i gracze z permisja np: kamien.sk nie muszą wykopywac kamienia. Pozdrawiam Dominik a i Z góry dziękuję 

Proszę, oto skrypt:

on first join:
	set {blokada::wykopanyKamien::%player%} to 0

on command:
	if command is not "msg" or "m" or "r":
		stop
	if player has permission "kamien.sk":
		stop
	if {blokada::wykopanyKamien::%player%} is not set:
		stop
	cancel event
	send "&cAby móc pisać do innych, musisz mieć wykopane 200 kamienia &6(&e%{blokada::wykopanyKamien::%player%}%&6/&e200&6)" to player
	
on chat:
	if player has permission "kamien.sk":
		stop
	if {blokada::wykopanyKamien::%player%} is not set:
		stop
	cancel event
	send "&cAby móc pisać na czacie, musisz mieć wykopane 200 kamienia &6(&e%{blokada::wykopanyKamien::%player%}%&6/&e200&6)" to player
	
on mine of stone:
	if {blokada::wykopanyKamien::%player%} is not set:
		stop
	add 1 to {blokada::wykopanyKamien::%player%}
	if {blokada::wykopanyKamien::%player%} is greater than or equal to 200:
		clear {blokada::wykopanyKamien::%player%}
		send "&aJuz możesz &6pisać &ana czacie i wykonywać komendy&7:" to player
		send "&7- &b/msg &e(&6/m)" to player
		send "&7- &b/r" to player