wedka nielota (szybko prosze)

W dniu 15.06.2024 o 15:18, _SpoconyPonczus_ napisał:

chce zrobic takie cos ze jak zarzuci sie na jakiegos gracza haczyk z wedki chyba wiadomo o co chodzi to ze poki ma ten haczyk zaczepiony to nie moze skakac
czy moglby dac mi ktos gotowy skrypt?

Proszę bardzo. Skrypt był częściowo testowany - testowałem wędkę jedynie na samym sobie.

Do działania skryptu wymagane są dodatek skript-reflect i silnik Paper (bądź dowolny jego fork).

import:
	org.bukkit.event.player.PlayerFishEvent
	org.bukkit.event.player.PlayerFishEvent$State as PlayerFishEventState
	org.bukkit.event.entity.ProjectileHitEvent
	
PlayerFishEvent:
	event.getState() is PlayerFishEventState.CAUGHT_ENTITY or PlayerFishEventState.REEL_IN or PlayerFishEventState.FAILED_ATTEMPT
	set {_caughtEntity} to event.getCaught()
	{_caughtEntity} is a player
	clear {caughtWithRod::disabledJump::%{_caughtEntity}%}
	
ProjectileHitEvent:
	event.getEntity() is a fish hook
	set {_hitEntity} to event.getHitEntity()
	{_hitEntity} is a player
	set {caughtWithRod::disabledJump::%{_hitEntity}%} to true
	
disconnect:
	{caughtWithRod::disabledJump::%player%} is set
	clear {caughtWithRod::disabledJump::%player%}
	
player jump:
	{caughtWithRod::disabledJump::%player%} is set
	cancel event

Pojawia się jeszcze kwestia ewentualnych bugów przy zbyt dalekim odejściu graczy od siebie lub wyjściu złapanego gracza z serwera. Mogę jedynie powiedzieć, że w przypadku pierwszego problemu stan REEL_IN może to rozwiązywać, a w przypadku drugiego nasłuchiwanie do zdarzenia 'disconnect' powinno pomóc.

Pozdrawiam.

Ten temat został przeniesiony.