Topki

56 minut temu, koxmacius napisał:

Siemka, jesteś w stanie napisać mi skrypt na topki w gui ewentualnie polecić jakiś co napewno działa szukałem dużo ale nie mg nic znajsc co by działało chciałbym topki kili dedow zjedzonych koxow I wykopenego stone

Proszę uprzejmie. Skrypt nie był przeze mnie testowany. W razie chęci konfiguracji myślę, że całość jest zrozumiała.

Do działania skryptu wymagany jest skrypt pyraTOP REBORN autorstwa Pana Marudy. Artykuł opisujący ów skrypt znajduje się tutaj.

options:
	topListSize: 5

on join:
	set {topStatistics::kills::%player%} to 0 if {topStatistics::kills::%player%} is not set
	set {topStatistics::deaths::%player%} to 0 if {topStatistics::deaths::%player%} is not set
	set {topStatistics::eatenEnchantedApples::%player%} to 0 if {topStatistics::eatenEnchantedApples::%player%} is not set
	set {topStatistics::minedStone::%player%} to 0 if {topStatistics::minedStone::%player%} is not set
	
every 5 minutes:
	set {topList::kills::*} to createTop("topStatistics::kills", {@topListSize}, "&3[I]&7. &b[P]&7: &6[V]")
	set {topList::deaths::*} to createTop("topStatistics::deaths", {@topListSize}, "&3[I]&7. &b[P]&7: &6[V]")
	set {topList::eatenEnchantedApples::*} to createTop("topStatistics::eatenEnchantedApples", {@topListSize}, "&3[I]&7. &b[P]&7: &6[V]")
	set {topList::minedStone::*} to createTop("topStatistics::minedStone", {@topListSize}, "&3[I]&7. &b[P]&7: &6[V]")

on death of player:
	add 1 to {topStatistics::deaths::%victim%}
	attacker is a player
	add 1 to {topStatistics::kills::%attacker%}
	
on consume of enchanted golden apple:
	add 1 to {topStatistics::eatenEnchantedApples::%player%}
	
on break of stone:
	add 1 to {topStatistics::minedStone::%player%}
		
command /top:
	executable by: players
	trigger:
		set {_topGUI} to chest inventory with 3 rows named "&6&lRankingi graczy"
		set slot (integers between 0 and 26) of {_topGUI} to gray stained glass pane
		set slot (4, 13 and 22) of {_topGUI} to white stained glass pane
		set slot 11 of {_topGUI} to iron sword named "&cNajwięcej zabójstw" with lore {topList::kills::*}
		set slot 12 of {_topGUI} to skeleton skull named "&cNajwięcej śmierci" with lore {topList::deaths::*}
		set slot 14 of {_topGUI} to enchanted golden apple named "&cNajwięcej zjedzonych złotych jabłek" with lore {topList::eatenEnchantedApples::*}
		set slot 15 of {_topGUI} to iron pickaxe named "&cNajwięcej wykopanego kamienia" with lore {topList::minedStone::*}
		open {_topGUI} to player

Jedna uwaga na koniec ode mnie.
Na początku skrypt będzie wyświetlał jedną wielką listę zawierającą "<none>", jednakże wystarczy dać mu "popracować" przez 5 minut i rankingi po tym czasie powinny zostać utworzone.