Skrypt/plugin zeby postawiony przez gracza Cobblestone po danym czasie znikał i wracal do eq

options:
	blockTime: 5
on join:
	loop {MagicStone::Player::%player%::blocks::*}:
		if block at loop-value is cobblestone:
			delete block at loop-value
		clear {MagicStone::Block::%loop-value%}
	clear {MagicStone::Player::%player%::blocks::*}
	set slot 8 of player to 64 cobblestone named "&eMagiczny kamień"
on inventory click:
	if event-inventory is player's inventory:
		if index of clicked slot is 7 or 8:
			cancel event
on swap hand items:
	if name of player's tool is "&eMagiczny kamień":
		cancel event
on place:
	if name of player's held item is "&eMagiczny kamień":
		if amount of cobblestone named "&eMagiczny kamień" in player's inventory is 1:
			cancel event
			stop
		add event-block to {MagicStone::Player::%player%::blocks::*}
		set {MagicStone::Block::%event-block%} to player
		wait {@blockTime} seconds
		if {MagicStone::Block::%event-block%} is not set:
			stop
		remove event-block from {MagicStone::Player::%player%::blocks::*}
		clear {MagicStone::Block::%event-block%}
		add 1 cobblestone named "&eMagiczny kamień" to player
		if event-block is cobblestone:
			delete event-block
on break:
	if {MagicStone::Block::%event-block%} is set:
		delete drops
		add 1 cobblestone named "&eMagiczny kamień" to player
		remove event-block from {MagicStone::Player::%{MagicStone::Block::%event-block%}%::blocks::*}
		clear {MagicStone::Block::%event-block%}
on death:
	if victim is a player:
		remove all cobblestone named "&eMagiczny kamień" from drops
on respawn:
	wait a tick
	set slot 8 of player to 64 cobblestone named "&eMagiczny kamień"
on pickup:
	if name of event-item is "&eMagiczny kamień":
		cancel event
		delete item
on drop:
	if name of event-item is "&eMagiczny kamień":
		cancel event

Dzieki za skrypt, działa  ale są bledy:

https://zapodaj.net/8fe1c61ed3cc3.png.html

czy trzeba instalowac jakies dodadkowe pluginy ?

Dodatki chyba zbędne. Skrypt pisany pod Skript 2.6.4

No oki to ignoruje te bledy. Wazne, że działa bardzo dziekuje nie sadzilem ze to taki duzy skrypt wyjdzie . Temat mozna zamknąć chyba, że ktoś chcialby napisac/udostepnic mi skrypt na to samo ale z wodą. (po postawieniu wyswietlala by sie wiadomosc &CTwoja woda zniknie za pare sekund!.