Sklep Tokeny

Ten temat został przeniesiony.

on join:
	if {tokeny::%player%} is not set:
		set {tokeny::%player%} to 0
command /tokeny [<text="stan">] [<text>] [<text>]:
	trigger:
		if arg 1 is "stan":
			if arg 2 is not set:
				if sender is not a player:
					send "&cKonsola nie ma tokenów."
					stop
				if player doesn't have permission "tokeny.stan" or "tokeny.admin":
					send "&cBrak uprawnień."
					stop
				send "&7Twoje tokeny: &c%{tokeny::%player%}%"
				stop
			if sender is a player:
				if player doesn't have permission "tokeny.stan.gracze" or "tokeny.admin":
					execute player command "/tokeny stan"
					stop
			if {tokeny::%arg 2%} is not set:
				send "&cNie znaleziono gracza."
				stop
			send "&7Tokeny gracza &e%arg 2%&7: &c%{tokeny::%arg 2%}%"
			stop
		if arg 1 is "dodaj":
			if sender is a player:
				if player doesn't have permission "tokeny.dodaj" or "tokeny.admin":
					send "&cBrak uprawnień."
					stop
			if arg 2 is not set:
				send "&cPoprawne użycie: &7/tokeny daj <gracz> <ilość>"
				stop
			if arg 3 is not set:
				send "&cPoprawne użycie: &7/tokeny daj <gracz> <ilość>"
				stop
			if {tokeny::%arg 2%} is not set:
				send "&cNie znaleziono gracza."
				stop
			if arg 3 parsed as integer is not set:
				send "&cIlość musi być liczbą całkowitą większą niż 0."
				stop
			if arg 3 parsed as integer is less than 1:
				send "&cIlość musi być liczbą większą niż 0."
				stop
			add arg 3 parsed as integer to {tokeny::%arg 2%}
			send "&7Dodałeś &c%arg 3% &7tokenów graczowi &e%arg 2%&7."
			if arg 2 parsed as player is set:
				send "&7Otrzymałeś &c%arg 3% &7tokenów." to arg 2 parsed as player
			stop
		if arg 1 is "usun":
			if sender is a player:
				if player doesn't have permission "tokeny.usun" or "tokeny.admin":
					send "&cBrak uprawnień."
					stop
			if arg 2 is not set:
				send "&cPoprawne użycie: &7/tokeny zabierz <gracz> <ilość>"
				stop
			if arg 3 is not set:
				send "&cPoprawne użycie: &7/tokeny zabierz <gracz> <ilość>"
				stop
			if {tokeny::%arg 2%} is not set:
				send "&cNie znaleziono gracza."
				stop
			if arg 3 parsed as integer is not set:
				send "&cIlość musi być liczbą całkowitą większą niż 0."
				stop
			if arg 3 parsed as integer is less than 1:
				send "&cIlość musi być liczbą większą niż 0."
				stop
			if {tokeny::%arg 2%} is 0:
				send "&cGracz &e%arg 2%&7 ma &c0 &7tokenów."
				stop
			set {_tk} to arg 3 parsed as integer
			if {_tk} is more than {tokeny::%arg 2%}:
				set {_tk} to {tokeny::%arg 2%}
			remove {_tk} from {tokeny::%arg 2%}
			send "&7Usunąłeś &c%{_tk}% &7tokenów graczowi &e%arg 2%&7."
			if arg 2 parsed as player is set:
				send "&7Usunięto &c%{_tk}% &7tokenów z Twojego konta." to arg 2 parsed as player
			stop
		if arg 1 is "resetuj":
			if sender is a player:
				if player doesn't have permission "tokeny.resetuj" or "tokeny.admin":
					send "&cBrak uprawnień."
					stop
			if arg 2 is not set:
				send "&cPoprawne użycie: &7/tokeny resetuj <gracz>"
				stop
			if {tokeny::%arg 2%} is not set:
				send "&cNie znaleziono gracza."
				stop
			set {tokeny::%arg 2%} to 0
			send "&7Zresetowałeś tokeny graczowi &e%arg 2%&7."
			if arg 2 parsed as player is set:
				send "&7Twoje tokeny zostały zresetowane." to arg 2 parsed as player
			stop

Komendy:

/tokeny [stan] - tokeny.stan / tokeny.admin
/tokeny stan <gracz> - tokeny.stan.gracze / tokeny.admin
/tokeny dodaj <gracz> <ilosc> - tokeny.dodaj / tokeny.admin
/tokeny usun <gracz> <ilosc> - tokeny.usun / tokeny.admin
/tokeny resetuj <gracz> - tokeny.resetuj / tokeny.admin