GUI z zestawami

5 godzin temu, naujan napisał:

Witam, zrobiłby mi ktoś skrypt, w którym dzięki komendzie /sety odpalało by się GUI z 4 rzędami. Na miejscu bodajże 31 (dolny środek) znajdował by się jasnozielony barwnik, nazwany " &a&lDodaj sety " , reszta paska na którym się znajduje barwnik to będą ciemno szare szyby. 

GUI poza szybami i barwnikiem, to miejsce na set. Chciałbym żeby gracz odpalający komendę miał możliwość wsadzenia seta w GUI. Po kliknięciu barwnika, zawartość GUI (poza dolnym paskiem) zostanie przekazana wszystkim graczom.

Z Góry dziękuje.

Chciałbym się upewnić czy dobrze zrozumiałem treść zlecenia.
Więc tak: gracz może wsadzić dowolne elementy zbroi do tego GUI, a po kliknięciu barwnika GUI się zamyka (to sobie dopowiedziałem) i każdy z graczy otrzymuje tę zbroje.

Pojawiają się więc dwa pytania:

1. Czy gracz wkładający zbroję traci ją bezpowrotnie?
2. Co jeśli któryś z graczy nie posiada miejsca w ekwipunku na zbroję? Jest ona wyrzucana na ziemi czy też po prostu nie jest dawana? A może coś innego się dzieje?

Jeśli Pan może, proszę doprecyzować co skrypt dokładnie ma robić.

Pozdrawiam.

Oczywiście, 

Zestaw przedmiotów ma również trafić do gracza wykonującego komendę, oraz przedmioty nie mają być dawane w raize braku miejsca, ponieważ w tym przypadku to nie powinno mieć miejsca. 

Przepraszam za niedoprecyzowanie, i mam nadzieje że teraz wszystko się zgadza

Pozdrawiam

5 godzin temu, naujan napisał:

Oczywiście, 

Zestaw przedmiotów ma również trafić do gracza wykonującego komendę, oraz przedmioty nie mają być dawane w raize braku miejsca, ponieważ w tym przypadku to nie powinno mieć miejsca. 

Przepraszam za niedoprecyzowanie, i mam nadzieje że teraz wszystko się zgadza

Pozdrawiam

Nic się nie stało. Proszę, oto skrypt. Co prawda testowałem go na samym sobie, ale z tego co widzę, powinien działać bezproblemowo.

options:
	GUIName: &aSety

command /sety:
	executable by: players
	trigger:
		set {_gui} to chest inventory with 4 rows named "{@GUIName}"
		set slots (integers from 27 to 35) of {_gui} to dark gray glass pane named ""
		set slot 31 of {_gui} to lime dye named "&a&lDodaj sety"
		open {_gui} to player

inventory click:
	event-inventory is not player's inventory
	name of event-inventory is "{@GUIName}"
	index of clicked slot is between 27 and 35
	cancel event
	index of clicked slot is 31
	set {_items::*} to (slots (integers from 0 to 26) of player's top inventory) where [input is not air]
	close player's inventory
	if size of {_items::*} = 0:
		send "&6Nie włożyłeś jakichkolwiek przedmiotów do GUI." to player
		stop
	loop all players where [input is not player]:
		if loop-player has enough space for {_items::*}:
			send "&aOtrzymałeś &6%size of {_items::*}% &aróżnych przedmiotów od &b%player%&a." to loop-player
			continue
		send "&6Otrzymałeś &e%size of {_items::*}% &6różnych przedmiotów od &b%player%&6. Niestety, nie posiadasz na nie wystarczająco dużo miejsca w ekwipunku." to loop-player
	if player doesn't have enough space for {_items::*}:
		send "&6Niestety, nie posiadasz wystarczająco dużo miejsca w ekwipunku na przedmioty, które dałeś wszystkim graczom." to player
	give {_items::*} to all players
	send "&aWręczyłeś innym graczom &6%size of {_items::*}% &aróżnych przedmiotów." to player

Gdyby wystąpiły jakieś błędy lub pojawiły się problemy z tym skryptem, proszę śmiało pisać.

Pozdrawiam.

Dziękuje bardzo, wszystko działa poprawnie.

Pozdrawiam