Sklep za itemy

Ten temat został przeniesiony.

ja ci zrobię, ale mało podałeś informacji co ma być w tym sklepie, dałeś tylko walutę..

23 godziny temu, SkryptExpert napisał:

ja ci zrobię, ale mało podałeś informacji co ma być w tym sklepie, dałeś tylko walutę..

Kilka uwag ode mnie.

1. Utworzenie GUI to jedno, trzeba jeszcze je otworzyć graczom.
2. W skrypcie brakuje sekcji 'options', która powinna zawierać ceny przedmiotów.
3. Sprawdzanie ilości waluty w ekwipunku gracza przy pomocy 'has more than' jest błędem, ponieważ gracz nie będzie w stanie kupić przedmiotu gdy posiada dokładnie wymaganą ilość waluty.
4. Indeksacja pięciowierszowego ekwipunku kończy się na indeksie równym 44, nie 45.
5. Tworzenie zbędnych wcięć w kodzie warunkami jest złą praktyką. Zalecam korzystać z tzw. 'inline conditionals'. Przykład poniżej.

Reszta zmian to zmiany według moich preferencji, więc proszę się tym nie przejmować.

Podpinam się do prośby o sprecyzowanie zlecenia, to znaczy jakie przedmioty mają się znaleźć w sklepie.

options:
	price1: 10
	price2: 5
	currency: emerald of unbreaking 10 named "&2Odłamek"

command /sklep [<text>]:
	executable by: players
	trigger:
		set {_gui} to chest inventory with 5 rows named "&2Sklep za odłamki"
		set slot (integers from 0 to 44) of {_gui} to green stained glass pane named "&7"
		set slot 21 of {_gui} to diamond sword named "&aPrzykładowy item" with lore "{@price1} odłamków"
		set slot 23 of {_gui} to diamond named "&aDrugi przykładowy item" with lore "{@price2} odłamków"
		open {_gui} to player

on inventory click:
	event-inventory is not player's inventory
	name of event-inventory is "&2Sklep za odłamki"
	cancel event
	if index of clicked slot is 21:
		player has {@price1} of {@currency}
		remove {@price1} of {@currency} from player's inventory
		give diamond sword to player
	else if index of clicked slot is 23:
		player has {@price2} of {@currency}
		remove {@price2} of {@currency} from player's inventory
		give diamond to player

Pozdrawiam.

W dniu 8.07.2024 o 11:23, Kormic napisał: