skrypt na miecz z efektami

24 minuty temu, feksuu napisał:

prosze o skrypt z mieczem który można ustawić jaki to miecz w skrypcie oraz jaki efekt ma dawac. cooldown 25 sekund

Można prosić o więcej szczegółów? W jaki sposób i komu ma być nadawany ten efekt? Do czego ma być zastosowany cooldown 25-sekundowy?

zeby efekt po uderzeniu był skierowany do uderzonego gracza

18 minut temu, feksuu napisał:

zeby efekt po uderzeniu był skierowany do uderzonego gracza

W takim razie proszę uprzejmie. Skrypt nie był testowany.

Sekcję konfiguracyjna skryptu znajduje się na samej górze. Listę efektów mikstur dostępnych w Skript można znaleźć tutaj.

Jeśli jest taka potrzeba, można dodać na końcu 26. linijki ('apply potion [...]') frazę 'replacing existing effect'. Dzięki temu nadany efekt nie nałoży się na istniejący już, a go zastąpi.

options:
	# Typ przedmiotu (drewniany miecz, żelazna łopata, itd.)
	swordType: diamond sword
	# Nazwa przedmiotu
	swordName: "&6Miecz"
	# Lore przedmiotu
	swordLore: "&aLinijka nr 1", "&bLinijka nr 2" and "&cLinijka nr 3"
	# Cooldown nadawania efektu przy atakowaniu
	swordEffectCooldown: 25 seconds
	# Typ nadawanego efektu
	swordEffectType: poison
	# Poziom nadawanego efektu
	swordEffectTier: 2
	# Długość trwania nadanego efektu
	swordEffectDuration: 10 seconds

on damage of player:
	attacker is a player
	type of attacker's tool is {@swordType}
	name of attacker's tool is {@swordName}
	lore of attacker's tool is {@swordLore}
	if {swordEffect::cooldown::%attacker's uuid%} is set:
		difference between {swordEffect::cooldown::%attacker's uuid%} and now is smaller than {@swordEffectCooldown}
		stop
	set {swordEffect::cooldown::%attacker's uuid%} to now
	apply potion of {@swordEffectType} of tier {@swordEffectTier} to victim for {@swordEffectDuration}
	
command /effectsword:
	executable by: players
	permission: server.command.effectsword
	permission message: &cNie posiadasz wystarczających uprawnień do wykonania tej komendy.
	trigger:
		give player {@swordType} named {@swordName} with lore {@swordLore}

Pozdrawiam.