skrypt różdżkę teleportacyjną

9 godzin temu, feksuu napisał:

mógłby ktoś napisać skrypt na różdżke ktora tepa tam gdzie sie wskazuje w minecrafcie żeby, miała 2 użycia bardzo proszę 

Proszę uprzejmie. Skrypt był testowany.

Aby otrzymać różdżkę, wystarczy wykonać komendę /getwand. Proszę mieć na względzie, że wymagana jest permisja do jej użycia. W razie potrzeby można spokojnie usunąć konfigurację komendy ('permission' i 'permission message').

options:
	wandItem: stick
	wandName: &bRóżdżka teleportacji
	wandMaxDurability: 2
	wandDurabilityLore: &7Pozostało użyć

command /getwand:
	executable by: players
	permission: server.command.getwand
	permission message: &cNie posiadasz wystarczających uprawnień do użycia tej komendy.
	trigger:
		set {_wand} to {@wandItem} named "{@wandName}"
		set lore of {_wand} to "{@wandDurabilityLore}: &a{@wandMaxDurability}"
		give {_wand} to player
		
on right click:
	targeted block is set
	type of player's tool is {@wandItem}
	name of player's tool is "{@wandName}"
	teleport player above targeted block
	set {_splitLore::*} to (uncoloured line 1 of lore of player's tool) split at " "
	set {_usagesLeft} to {_splitLore::3} parsed as number
	if {_usagesLeft} = 1:
		remove 1 of player's tool from player's inventory
		send "&cTwoja różdżka teleportacji uległa zniszczeniu." to player
		wait 1 tick
		play sound "ENTITY_ITEM_BREAK" to player
		stop
	subtract 1 from {_usagesLeft}
	set lore of player's tool to "{@wandDurabilityLore}: &6%{_usagesLeft}%"
	wait 1 tick
	play sound "ENTITY_ENDERMAN_TELEPORT" to player

Pozdrawiam.