Wedka Surferka z anarchii

Ten temat został przeniesiony.

?

Nwm czy o to ci chodzi ale jak chcesz to masz!

Jak ci Sie podoba napisz i daj <3!


Skrypt:

---------------------------------------------------------------------------------------------------------





 

on fish:
    if fishing state is reel in:
        if unformatted name of player's tool is "Wendka Surfera (Kliknij Prawy Przycisk)":
            if lore of player's tool contains "&8To Wendka Surfera Jest on unikalny!":
                if {grapple::cooldown::%player's uuid%} isn't set:
                    set {grapple::falldamage::%player's uuid%} to true
                    push player upwards at speed 1
                    push player forwards at speed 2
                    damage player's tool by 2
                    set {grapple::cooldown::%player's uuid%} to 5 seconds from now
                    wait 5 seconds
                    delete {grapple::cooldown::%player's uuid%}
                    delete {grapple::falldamage::%player's uuid%}
                else if {grapple::cooldown::%player's uuid%} is set:
                    send "&cNastępne użycie możesz wykonać za. &7(%difference between now and {grapple::cooldown::%player's uuid%}%)" to player
                    set {_item} to player's tool
                    set player's tool to air
                    set player's tool to {_item}

on swap hand item:
    if unformatted name of player's tool is "Wendka Surfera (Kliknij Prawy Przycisk)":
        if lore of player's tool contains "&8To Wendka Surfera Jest on unikalny!":
            cancel event
            send "%nl%&cUwaga! Nie można Używać tego Itemu w 2 łapce!%nl%"

command /dajwendkesurfera [<text>]:
    permission: Dawido.WendkaSurfera
    permission message: &4&lERROR ---> &c&lNie Masz Permisji! &7(Dawido.WendkaSurfera)
    trigger:
        give fishing rod of unbreaking 10 named "&6Wendka Surfera &7(&eKliknij Prawy Przycisk&7)" with lore "&8To Wendka Surfera Jest on unikalny!" to player

on damage:
    if "%damage cause%" is "fall":
        if {grapple::cooldown::%victim's uuid%} is set:
            cancel event

on enchant prepare:
    if event-item is fishing rod:
        if lore of event-item contains "&8To Wendka Surfera Jest on unikalny!":
            set enchant offer 1, 2 and 3 to thorns 1
            set the cost of enchant offer 1, 2 and 3 to 100000

on anvil prepare:
    if lore of slot 0 of event-inventory contains "&8To Wendka Surfera Jest on unikalny!":
        set repair cost of event-inventory to -1