Problem ze skryptem

@Gliczdziękuje za wstawienie w code

@Mejkalt jako że jest to temat typu "nie wiem ale chce się dowiedzieć to omówię to z Tb:

Linia 2:
 

on join:
	if {woda.%player%} is not set
	set {woda.%player%} to 100

tutaj wszystko jest gut z wyjątkiem tego że "if jest nie potrzebne" :
 

on join:
	{woda.%player%} is not set
	set {woda.%player%} to 100

jeżeli zapisujesz "if" musisz użyć po linii dwukropka ":" a następną linijke zacząć od TAB (lub 4 spacji zależy jak tam sobie wolisz tabować:

 

on join:
	if {woda.%player%} is not set:
		set {woda.%player%} to 100

Linia 24 brakowało "is" :

if block at loop-player's location is water:

linia 26:
 

Jeżeli wysypie się linia z "if" (24)  linia z "else" nie działa (26)

Po  naprawie 24/26 linii Linia 25 oraz 27:
 

25:
add (random integer bwtewwn 1 and 5) to {woda.%loop-player%}
27:
remove (random integer bwetween 1 and 5) from {woda.%loop-player%}

Literówki powinno być "between"
 

			add (random integer between 1 and 5) to {woda.%loop-player%}
		else:
			remove (random integer between 1 and 5) from {woda.%loop-player%}

Linia 31:
 

set {woda.%loo-player%} to 0

Literówka powinno być : "loop-player" 

 

set {woda.%loop-player%} to 0

cały kod poprawiony:
 

on join:
	if {woda.%player%} is not set:
		set {woda.%player%} to 100
	
command /statystyki [<offlineplayer>]:
	aliases: stats, stat, staty
	trigger:
		if arg 1 is not set:
			send "&b[-------------------]"
			send " &eNick gracza: &f%player%"
			send " &eNawodnienie: &f%{woda.%player%}%"
			send "&b[-------------------]"
		else:
			if {woda.%arg 1%} is not set:
				send "&cBrak gracza w bazie!"
				stop
			send "&b[-------------------]"
			send " &eNick gracza: &f%arg 1%"
			send " &eNawodnienie: &f%{woda.%arg 1%}%"
			send "&b[-------------------]"
			
every 20 seconds:
	loop all players:
		if block at loop-player's location is water:
			add (random integer between 1 and 5) to {woda.%loop-player%}
		else:
			remove (random integer between 1 and 5) from {woda.%loop-player%}
		if {woda.%loop-player%} > 100:
			set {woda.%loop-player%} to 100
		if {woda.%loop-player%} <= 0:
			set {woda.%loop-player%} to 0
			apply nausea 3 to loop-player for 20 seconds
			apply poison 1 to loop-player for 20 seconds
			
on drink:
	add 60 to {woda.%player%}
	if {woda.%player%} > 100:
		set {woda.%player%} to 100
	remove nausea from player
	remove poison from player

Dzięki bardzo

Problem został rozwiązany.