Skript na punch administracji

1 minutę temu, AxonGames napisał:

czesc chcialbym otrzymac skrypt na punch administracji, jesli admin posiada permisjie admin.use, moze on zostac wyrzucony do gory nieba przed wybuchem effekt wybuchy tnt, i zeby punch staff musi gracz miec permisje admin.punch, wysyla wiadomosc ze "nazwa admina zostal wyrzucony do nieba przez {nazwe gracza ktory to zrobil}, i cooldown 1 minuta przed kolejnym wyrzuceniem adminow dziekuje

Trochę to pokomplikowałeś. Wyjaśnij jeszcze raz. Jak to ma działać, kto musi mieć jaką permisję, na kogo ma być nałożony cooldown, itd.

Po prostu oczekuję szczegółowych informacji, aby nie było potrzeby dopytywania.

8 minut temu, Kormic napisał:

Trochę to pokomplikowałeś. Wyjaśnij jeszcze raz. Jak to ma działać, kto musi mieć jaką permisję, na kogo ma być nałożony cooldown, itd.

Po prostu oczekuję szczegółowych informacji, aby nie było potrzeby dopytywania.

No to tak, po uderzeniu admina inaczej punch, pojawia sie efekt tnt i admin zostaje wyrzucony do nieba, zeby uderzyć jakiegos admina, musi ten admin posiadac permisje (admin.use), a gracz zeby uderzyc admina z tą permisja musi miec permisje (punch.use), wysyla sie wiadomosc '{nick admina} zostal wyrzucony do nieba przez {nick gracza}, potem cooldown jest nałożony na tego co uderzył admina.

20 minut temu, AxonGames napisał:

No to tak, po uderzeniu admina inaczej punch, pojawia sie efekt tnt, zeby uderzyć jakiegos admina, musi ten admin posiadac permisje (admin.use), a gracz zeby uderzyc admina z tą permisja musi miec permisje (punch.use), wysyla sie wiadomosc '{nick admina} zostal wyrzucony do nieba przez {nick gracza}, potem cooldown jest nałożony na tego co uderzył admina.

Proszę.

function translateTimespan(t: timespan) :: text:
	set {_t} to "%{_t}%"
	set {_eng::*} to "years", "year", "months", "month", "days", "day", "hours", "hour", "minutes", "minute", "seconds", "second" and " and "
	set {_pol::*} to "lat", "rok", "miesięcy", "miesiąc", "dni", "dzień", "godzin", "godzinę", "minut", "minutę", "sekund", "sekundę" and ", "
	loop {_eng::*}:
		replace all loop-value with {_pol::%loop-index%} in {_t}
	return {_t}

on damage of player:
	attacker is a player
	victim has permission "admin.use"
	if attacker doesn't have permission "punch.use":
		cancel event
		send "&cNie posiadasz wymaganej permisji! &6(punch.use)" to attacker
		stop
	{cooldownPunch::%attacker%} is set:
		difference between {cooldownPunch::%attacker%} and now is less than 1 minute
		cancel event
		set {_t} to {cooldownPunch::%attacker%}
		add 1 minute to {_t}
		send "&cMożesz ponownie podrzucić admina za &6%translateTimespan(difference between {_t} and now)%&c!" to attacker
		stop
	set {cooldownPunch::%attacker%} to now
	set damage to 0
	push victim upwards with speed 3
	broadcast "&e%victim% &6został wyrzucony w niebo przez &e%attacker%&6!"