Skrypt na /piecyk

11 minut temu, Jakuuuub napisał:

Może ktoś napisać skrypt na /piecyk?

Po wpisaniu tej komendy by się wyświetlać piec, tak jak np.: Jest to z craftingiem.

Mógłbym dać ci coś takiego,

command /piecyk:
	trigger:
		open furnace inventory named "Piecyk" to player

ale jak zauważysz, ten piec w ogóle nie działa, a w dodatku po jego zamknięciu cała jego zawartość jest utracona.

W takim wypadku przy użyciu tej komendy należałoby postawić przed graczem prawdziwy piecyk i przy zamknięciu okna zniszczyć go.

Skrypt:

command /piecyk:
	trigger:
		if targeted block is not set:
			send "&cNie ma odpowiedniego miejsca na postawienie piecyka!" to player
			stop
		if distance between targeted block and player is greater than or equal to 5:
			send "&cNamierzony blok jest zbyt daleko!" to player
			stop
		if block above targeted block is not air:
			send "&cNie ma wolnego miejsca nad namierzonym blokiem!" to player
			stop
		set {piecykLoc::%player%} to location at block above targeted block
		set block at {piecykLoc::%player%} to furnace
		open inventory of (block at {piecykLoc::%player%}) to player
		set {piecykUzycie::%player%} to true
		
on break of furnace:
	loop all players in radius 5 around block under event-block:
		if loop-player is event-player:
			continue
		if {piecykUzycie::%loop-player%} is set:
			if loop-player's targeted block is block under event-block:
				cancel event
		
on inventory close:
	if {piecykUzycie::%player%} is true:
		set block at {piecykLoc::%player%} to air
		clear {piecykUzycie::%player%} and {piecykLoc::%player%}

Informacja:

Ten skrypt jedynie powoduje, iż piec działa, natomiast zawartość po zamknięciu i tak przepada. Jeżeli chciałbyś ją zapisać, musiałbyś tworzyć nowe zmienne przy zamknięciu i zapisywać w nich slot od przepalanych przedmiotów, slot od paliwa oraz slot z przepalonymi przedmiotami.