Pytanie o plugin

18 minut temu, GOSTbusters28 napisał:

Wiem że nie dotyczy to scripta, ale poleciłby mi ktoś jakiś dobry skrypt na ekonomię? Potrzebuję tylko żeby można było sprzedawać oraz kupować przedmioty w sklepie na tabliczki. I jeszcze gdyby komuś się chciało to można dać link do jakiegoś poradnika jak skonfigurować dany plugin.  

1. Dobrze, ale co ten skrypt ma dodawać? Te tabliczki może stawiać każdy gracz czy jedynie będą one stawiane przez adminów?

2. Masz na myśli konfigurowanie każdego pluginu? Wszystkie pliki konfiguracyjne są unikalne.

Informacja dla moderacji:

Przepraszam za przypadkowe zgłoszenie, nie było ono zamierzone.

Teraz, Kormic napisał:

1. Dobrze, ale co ten skrypt ma dodawać? Te tabliczki może stawiać każdy gracz czy jedynie będą one stawiane przez adminów?

2. Masz na myśli konfigurowanie każdego pluginu? Wszystkie pliki konfiguracyjne są unikalne.

1. Chcę plugin na pieniądze czyli np 15 arbuzów sprzedaj za 20 kup za 30. I tabliczki mogą stawiać tylko admini. Po prostu żeby zrobić sklep na spawnie.

2. Nie, tylko tego na ekonomię.

Ten temat został przeniesiony.

28 minut temu, GOSTbusters28 napisał:

1. Chcę plugin na pieniądze czyli np 15 arbuzów sprzedaj za 20 kup za 30. I tabliczki mogą stawiać tylko admini. Po prostu żeby zrobić sklep na spawnie.

2. Nie, tylko tego na ekonomię.

Co do pluginów, wymagany oczywiście Skript, dodatkowo Essentials (może być EssentialsX) i Vault.

Skrypt:

on right click on sign:
	if uncoloured line 1 of clicked block is not "[Sklep]":
		stop
	if line 2 is empty:
		stop
	set {_item} to (uncoloured line 2 of clicked block) parsed as item
	if uncoloured line 3 of clicked block contains "Kup za:":
		set {_cena} to (uncoloured last (length of line 3 of clicked block - 8) characters of line 3 of clicked block) parsed as number
		if player's money is less than {_cena}:
			send "&cNie stać cię na to!" to player
			stop
		remove {_cena} from player's money
		give player {_item}
		send "&aPomyślnie zakupiłeś &6%{_item}% za &e%{_cena}%&a$!" to player
	else if uncoloured line 3 of clicked block contains "Sprzedaj za:":
		set {_cena} to (uncoloured last (length of line 3 of clicked block - 13) characters of line 3 of clicked block) parsed as number
		if player doesn't have {_item}:
			send "&cNie posiadasz wymaganych przedmiotów!" to player
			stop
		remove {_item} from player's inventory
		add {_cena} to player's money
		send "&aPomyślnie sprzedałeś &6%{_item}% &aza &e%{_cena}%&a$!" to player

Wzór tabliczki:

1. [Sklep]
2. %item type%
3. (Sprzedaj za|Kup za): %number%

Przykłady:

#1
1. [Sklep]
2. 64 diamond block
3. Kup za: 1000.99

#2
1. [Sklep]
2. 1 gold ingot
3. Sprzedaj za: 50

Jeśli będzie potrzeba, na tabliczce spokojnie mogą być używane kolory. W razie błędów daj znać.

PS.

Jeżeli planujesz coś większego z tabliczkami, wtedy już zalecam użycie pluginu (chociażby dobry jest SignShop, Essentials również posiada możliwość tworzenia tabliczek jako sklepów).

2 minuty temu, Kormic napisał:

Co do pluginów, wymagany oczywiście Skript, dodatkowo Essentials (może być EssentialsX) i Vault.

Skrypt:

on right click on sign:
	if uncoloured line 1 of clicked block is not "[Sklep]":
		stop
	if line 2 is empty:
		stop
	set {_item} to (uncoloured line 2 of clicked block) parsed as item
	if uncoloured line 3 of clicked block contains "Kup za:":
		set {_cena} to (uncoloured last (length of line 3 of clicked block - 8) characters of line 3 of clicked block) parsed as number
		if player's money is less than {_cena}:
			send "&cNie stać cię na to!" to player
			stop
		remove {_cena} from player's money
		give player {_item}
		send "&aPomyślnie zakupiłeś &6%{_item}% za &e%{_cena}%&a$!" to player
	else if uncoloured line 3 of clicked block contains "Sprzedaj za:":
		set {_cena} to (uncoloured last (length of line 3 of clicked block - 13) characters of line 3 of clicked block) parsed as number
		if player doesn't have {_item}:
			send "&cNie posiadasz wymaganych przedmiotów!" to player
			stop
		remove {_item} from player's inventory
		add {_cena} to player's money
		send "&aPomyślnie sprzedałeś &6%{_item}% &aza &e%{_cena}%&a$!" to player

Wzór tabliczki:

1. [Sklep]
2. %item%
3. (Sprzedaj za|Kup za): %number%

Przykłady:

#1
1. [Sklep]
2. 64 diamond block
3. Kup za: 1000.99

#2
1. [Sklep]
2. 1 gold ingot
3. Sprzedaj za: 50

Jeśli będzie potrzeba, na tabliczce spokojnie mogą być używane kolory. W razie błędów daj znać.

PS.

Jeżeli planujesz coś większego z tabliczkami, wtedy już zalecam użycie pluginu (chociażby dobry jest SignShop, Essentials również posiada możliwość tworzenia tabliczek jako sklepów).

Dzięki wielkie!

@Kormicpo co ten skrypt skoro essentials ma takie same tabliczki?

15 minut temu, Helios1993 napisał:

@Kormicpo co ten skrypt skoro essentials ma takie same tabliczki?

Autor wątku chciał prosty skrypt na kupno oraz sprzedaż itemów poprzez tabliczki. Jeżeli skrypt zajmuje niewiele ponad 20 linijek, zrobienie go nie jest niczym trudnym.

Zdaję sobie sprawę z faktu, iż m.in. Essentials zawiera tabliczki. Przeczytaj proszę post scriptum załączone do mojego postu.