Skrypt

22 minuty temu, Koksu123 napisał:

Osoba ktora wpisze /os lub /osiagniecia

to wyswietla sie gui

https://imgur.com/a/iecigr1

mniej wiecej cos takiego

gdy kliknie w stone to dostanie kiliof efficiency 6, unbreaking 3 i fortune 3

lecz aby odebrac nagrode musi miec wykopane 100k stone

edit.

Kormic twoje bojowe zadanie 

 

1. Nie proś mnie osobiście o zrobienie skryptu, bo to jest świństwo wobec innych chcących ci pomóc osób na forum. Postaw się na ich miejscu i pomyśl jak byś się czuł, gdybyś chciał pomóc komuś, ale ten ktoś już poprosił konkretną osobę do pomocy.

2. Skrypt:

command /osiagniecia:
	aliases: /os
	trigger:
		open chest inventory with 3 rows named "&aOsiagniecia" to player
		loop 27 times:
			set slot loop-number - 1 of player's current inventory to black stained glass pane named " "
		if {osiagniecia::lista::%player%::*} doesn't contain "osiagniecieStone":	
			if {osiagniecia::wykopanyStone::%player%} is not set:
				set {osiagniecia::wykopanyStone::%player%} to 0
		if {osiagniecia::lista::%player%::*} doesn't contain "osiagniecieStone":
			if {osiagniecia::wykopanyStone::%player%} is greater than or equal to 100000:
				set slot 13 of player's current inventory to stone named "&aWykop 100k stone" with lore "&aWykopales &6100k &astone!" and "" and "&7Kliknij, aby odebrac &anagrode&7!"
			else:
				set slot 13 of player's current inventory to stone named "&cWykop 100k stone" with lore "&7Musisz wykopac &6100k &7stone, aby moc odebrac nagrode!" and "" and "&7Twoj postep: &6%{osiagniecia::wykopanyStone::%player%}%&e/&6100000"
		else:
			set slot 13 of player's current inventory to stone named "&2Wykop 100k stone" with lore "aJuz zdobyles te osiagniecie!"

on inventory click:
	if name of player's current inventory is not "&aOsiagniecia":
		stop
	if clicked inventory is player's inventory:
		stop
	cancel event
	if clicked slot is 13:
		if {osiagniecia::lista::%player%::*} contains "osiagniecieStone":
			send "&cJuz odebrales nagrode za to osiagniecie!" to player
			stop
		if {osiagniecia::wykopanyStone::%player%} is less than 100000:
			send "&cNie mozesz odebrac nagrody za to osiagniecie!" to player
			stop
		give player 1 diamond pickaxe of efficiency 6, unbreaking 3, fortune 3
		add "osiagniecieStone" to {osiagniecia::lista::%player%::*}
		clear {osiagniecia::wykopanyStone::%player%}
		close player's inventory
		send "&aOdebrales nagrode za osiagniecie!" to player
		
on break of stone:
	if {osiagniecia::lista::%player%::*} contains "osiagniecieStone":
		stop
	add 1 to {osiagniecia::wykopanyStone::%player%}
	if {osiagniecia::wykopanyStone::%player%} is 100000:
		send "&aZdobyles nowe osiagniecie! Sprawdz je pod &e/osiagniecia&a!" to player

Jeśli coś nie będzie działało, daj znać.

@Kormic

Wszystko dziala!

KC

@Kormic

jednak jak wykopiesz juz 100k stone i chcesz odebrac nagrode to da sie wyjmowac itemki z gui a kilofa ci nie daje

3 minuty temu, Koksu123 napisał:

@Kormic

jednak jak wykopiesz juz 100k stone i chcesz odebrac nagrode to da sie wyjmowac itemki z gui a kilofa ci nie daje

Dziwne, jest 'cancel event' w evencie 'on inventory click', więc nie powinno być możliwości wyjmowania itemów z GUI. Daj mi chwilę, przetestuję i zobaczę o co biega.

EDIT:

Przy okazji poprawiłem drzewa condictionali dla przejrzystości kodu. Tutaj poprawiony fragment, zamieniasz w komendzie /osiagniecia od linijki nr 7.

if {osiagniecia::lista::%player%::*} doesn't contain "osiagniecieStone":	
	if {osiagniecia::wykopanyStone::%player%} is not set:
		set {osiagniecia::wykopanyStone::%player%} to 0
if {osiagniecia::lista::%player%::*} contains "osiagniecieStone":
	set slot 13 of player's current inventory to stone named "&2Wykop 100k stone" with lore "aJuz zdobyles te osiagniecie!"
	stop
if {osiagniecia::wykopanyStone::%player%} is less than 100000:
	set slot 13 of player's current inventory to stone named "&cWykop 100k stone" with lore "&7Musisz wykopac &6100k &7stone, aby moc odebrac nagrode!" and "" and "&7Twoj postep: &6%{osiagniecia::wykopanyStone::%player%}%&e/&6100000"
	stop
set slot 13 of player's current inventory to stone named "&aWykop 100k stone" with lore "&aWykopales &6100k &astone!" and "" and "&7Kliknij, aby odebrac &anagrode&7!"

@Kormic

https://imgur.com/a/x6XiNUE

Teraz, Koksu123 napisał:

@Kormic

https://imgur.com/a/x6XiNUE

Sprawdziłem skrypt, wszystko świetnie działa, daje kilof, nie można wyjmować itemów, ogółem rzecz biorąc działa bez zarzutu.

command /osiagniecia:
	aliases: /os
	trigger:
		open chest inventory with 3 rows named "&aOsiagniecia" to player
		loop 27 times:
			set slot loop-number - 1 of player's current inventory to black stained glass pane named " "
		if {osiagniecia::lista::%player%::*} doesn't contain "osiagniecieStone":	
			if {osiagniecia::wykopanyStone::%player%} is not set:
				set {osiagniecia::wykopanyStone::%player%} to 0
		if {osiagniecia::lista::%player%::*} contains "osiagniecieStone":
			set slot 13 of player's current inventory to stone named "&2Wykop 100k stone" with lore "&aJuz zdobyles te osiagniecie!"
			stop
		if {osiagniecia::wykopanyStone::%player%} is less than 100000:
			set slot 13 of player's current inventory to stone named "&cWykop 100k stone" with lore "&7Musisz wykopac &6100k &7stone," and "&7aby moc odebrac nagrode!" and "" and "&7Twoj postep: &6%{osiagniecia::wykopanyStone::%player%}%&e/&6100000"
			stop
		set slot 13 of player's current inventory to stone named "&aWykop 100k stone" with lore "&aWykopales &6100k &astone!" and "" and "&7Kliknij, aby odebrac &anagrode&7!"

on inventory click:
	if name of player's current inventory is not "&aOsiagniecia":
		stop
	if clicked inventory is player's inventory:
		stop
	cancel event
	if clicked slot is 13:
		if {osiagniecia::lista::%player%::*} contains "osiagniecieStone":
			send "&cJuz odebrales nagrode za to osiagniecie!" to player
			stop
		if {osiagniecia::wykopanyStone::%player%} is less than 100000:
			send "&cNie mozesz odebrac nagrody za to osiagniecie!" to player
			stop
		give player 1 diamond pickaxe of efficiency 6, unbreaking 3, fortune 3
		add "osiagniecieStone" to {osiagniecia::lista::%player%::*}
		clear {osiagniecia::wykopanyStone::%player%}
		close player's inventory
		send "&aOdebrales nagrode za osiagniecie!" to player
		
on break of stone:
	if {osiagniecia::lista::%player%::*} contains "osiagniecieStone":
		stop
	add 1 to {osiagniecia::wykopanyStone::%player%}
	if {osiagniecia::wykopanyStone::%player%} is 100000:
		send "&aZdobyles nowe osiagniecie! Sprawdz je pod &e/osiagniecia&a!" to player

o teraz mi zadzialalo 

Problem został rozwiązany.