Skript na sklep

54 minuty temu, Cortix napisał:

Witam poszukuje skriptu na skyblock , aby opcja byla kupna pare stackow na raz, sprzedawanie wszystkiego ŚPM pojedynczo PPM , kupno LPM 

oczywiscie w gui

Zrobiłem przykład z cobblestonem, resztę dodasz sobie sam. Kod jest w miarę czytelny, powinieneś się odszukać w nim. Dodam, że najważniejsze rzeczy są oddzielone przerwami w kodzie dla ułatwienia tobie roboty. Cenę zakupu bruku za sztukę ustaliłem u góry, natomiast cena sprzedaży za sztukę jest 2 razy niższa, czyli wynosi 5. Wymagania masz na dole postu. Proszę:

options:
	cena-bruk: 10

command /sklep:
	trigger:
		open chest inventory with 4 rows named "&b&lSklep" to player
		loop 36 times:
			set slot loop-number - 1 of player's current inventory to white stained glass pane named " "
		loop integers between 10 and 16:
			set slot loop-integer of player's current inventory to air
		loop integers between 19 and 25:
			set slot loop-integer of player's current inventory to air
			
		set slot 10 of player's current inventory to cobblestone named "&aKup" with lore "&7Kliknij &eLPM&7, aby kupic &a1 &7sztuke bruku" and "&7Kliknij &6PPM&7, aby kupic &a64 &7sztuk bruku" and "" and "&aCena&7: &6{@cena-bruk}$&e/&6szt."
		set {_sellbruk} to ({@cena-bruk} / 2)
		set slot 19 of player's current inventory to cobblestone named "&cSprzedaj" with lore "&7Kliknij &eLPM&7, aby sprzedac &c1 &7sztuke bruku" and "&7Kliknij &6PPM&7, aby sprzedac &c64 &7sztuk bruku" and "&7Kliknij &cSPM&7, aby sprzedac &ccaly &7bruk w twoim EQ" and "" and "&cCena&7: &6%{_sellbruk}%$&e/&6szt."
		
		set slot 27 of player's current inventory to book named "&6Legenda&7:" with lore " &6LPM &7- &blewy przycisk myszy" and " &6PPM &7- &bprawy przycisk myszy" and " &6SPM &7- &bsrodkowy przycisk myszy"
		set slot 35 of player's current inventory to barrier named "&cAnuluj" with lore "&7Kliknij, aby &cwyjsc &7z oferty!"
		
on inventory click:
	if name of player's current inventory is not "&b&lSklep":
		stop
	if clicked inventory is not player's inventory:
		stop
	cancel event
	if clicked slot is 10:
	
		if click type is left mouse button:
			if player's money isn't greater than or equal to {@cena-bruk}:
				close player's inventory
				send "&cNie stac cie na to!" to player
				stop
			remove 10 from player's money
			if player can hold 1 cobblestone:
				give player 1 cobblestone
			else:
				drop 1 cobblestone at player
				
		if click type is right mouse button:
			set {_brukstack} to ({@cena-bruk} * 64)
			if player's money isn't greater than or equal to {_brukstack}:
				close player's inventory
				send "&cNie stac cie na to!" to player
				stop
			remove {_brukstack} from player's money
			if player can hold 64 cobblestone:	
				give player 64 cobblestone
			else:
				drop 64 cobblestone at player
				
	if clicked slot is 19:
	
		set {_sellbruk} to ({@cena-bruk} / 2)
		if click type is left mouse button:
			if player doesn't have 1 cobblestone:
				close player's inventory
				send "&cNie masz tylu surowcow!" to player
				stop
			remove 1 cobblestone from player's inventory
			add {_sellbruk} to player's money
			
		if click type is right mouse button:
			set {_brukstack} to ({_sellbruk} * 64)
			if player doesn't have 64 cobblestone:
				close player's inventory
				send "&cNie masz tylu surowcow!" to player
				stop
			remove 64 cobblestone from player's inventory
			add {_brukstack} to player's money
			
		if click type is middle mouse button:
			if player doesn't have 1 cobblestone:
				close player's inventory
				send "&cNie masz tylu surowcow!" to player
				stop
			set {_bruk} to amount of cobblestone in player's inventory
			set {_brukall} to ({_bruk} * {@cena-bruk})
			remove {_bruk} of cobblestone from player's inventory
			add {_brukall} to player's money

PS.

Dodam, że jest wymagana wersja Skripta to minimum 2.2-dev35. Również wymagany jest Vault oraz jakiś plugin wspierający ekonomię (np. Essentials).

Weź jak człowiek użyj ShopGUI+ a nie bawisz sie skryptami