Skrypt na sprawdzanie na 1.15.2

Ten temat został przeniesiony.

function bSprawdzGracza(sprawdzajacy: player, sprawdzany: player):
	
	send "Poprawnie wziales na sprawdzanie gracza %{_sprawdzany}%!" to {_sprawdzajacy}
	send "Jestes sprawdzany przez %{_sprawdzajacy}%!" to {_sprawdzany}
	#send "%{_sprawdzany}% jest sprawdzany przez %{_sprawdzajacy}%!" to all players

	set {bSprawdzanie::statusSprawdzania::%{_sprawdzany}%} to {_sprawdzajacy}
	set {bSprawdzanie::statusSprawdzania::%{_sprawdzajacy}%} to {_sprawdzany}

	teleport {_sprawdzajacy} to {bSprawdzanie::lokacjaSprawdzania}
	teleport {_sprawdzany} to {bSprawdzanie::lokacjaSprawdzania}

function bNadajCzystego(sprawdzajacy: player, sprawdzany: player):
	
	send "Poprawnie nadales czystego graczowi %{_sprawdzany}%!" to {_sprawdzajacy}
	send "Administrator %{_sprawdzajacy}% nie wykryl u Ciebie zadnych wspomagaczy, jestes wolny!" to {_sprawdzany}
	#send "%{_sprawdzajacy}% nie wykryl zadnych wspomagaczy u %{_sprawdzany}%!" to all players

	clear {bSprawdzanie::statusSprawdzania::%{_sprawdzany}%}
	clear {bSprawdzanie::statusSprawdzania::%{_sprawdzajacy}%}

	teleport {_sprawdzajacy} to (lokacja spawna)
	teleport {_sprawdzany} to (lokacja spawna)

function bZbanujCheaty(sprawdzajacy: player, sprawdzany: player):
	
	send "Poprawnie zbanowales %{_sprawdzany}% za cheaty!" to {_sprawdzajacy}
	#send "%{_sprawdzajacy}% wykryl cheaty u %{_sprawdzany}%!" to all players

	clear {bSprawdzanie::statusSprawdzania::%{_sprawdzany}%}
	clear {bSprawdzanie::statusSprawdzania::%{_sprawdzajacy}%}

	teleport {_sprawdzajacy} to (lokacja spawna)
	teleport {_sprawdzany} to (lokacja spawna)

	ban {_sprawdzany} due to "Cheaty wykryte podczas sprawdzania!%nl%Sprawdzal: %{_sprawdzajacy}%!" for 7 days

command /sprawdz [<offlineplayer>]:
	permission: sprawdanie.sprawdz
	permission message: Nie masz permisji!
	trigger:
		if arg 1 is not set:
			send "/sprawdz gracz"
			stop
		if arg 1 is not online:
			send "Podany gracz jest offline!"
			stop
		if {bSprawdzanie::statusSprawdzania::%arg 1%} is set:
			send "Ten gracz jest juz przez kogos sprawdzany!"
			stop
		if {bSprawdzanie::statusSprawdzania::%player%} is set:
			send "Sprawdzasz juz kogos!"
			stop
		if {bSprawdzanie::lokacjaSprawdzania} is not set:
			send "Miejsce sprawdzania nie jest ustawione!"
			stop
		bSprawdzGracza(player, arg 1)
		stop

command /czysty [<offlineplayer>]:
	permission: sprawdanie.czysty
	permission message: Nie masz permisji!
	trigger:
		if arg 1 is not set:
			send "/czysty gracz"
			stop
		if arg 1 is not online:
			send "Podany gracz jest offline!"
			stop
		if {bSprawdzanie::statusSprawdzania::%arg 1%} is not set:
			send "Ten gracz nie jest sprawdzany!"
			stop
		if {bSprawdzanie::statusSprawdzania::%player%} is not arg 1:
			send "Nie sprawdzasz tego gracza!"
			stop
		bNadajCzystego(player, arg 1)
		stop

command /cheaty [<offlineplayer>]:
	permission: sprawdanie.cheaty
	permission message: Nie masz permisji!
	trigger:
		if arg 1 is not set:
			send "/cheaty gracz"
			stop
		if arg 1 is not online:
			send "Podany gracz jest offline!"
			stop
		if {bSprawdzanie::statusSprawdzania::%arg 1%} is not set:
			send "Ten gracz nie jest sprawdzany!"
			stop
		if {bSprawdzanie::statusSprawdzania::%player%} is not arg 1:
			send "Nie sprawdzasz tego gracza!"
			stop
		bZbanujCheaty(player, arg 1)
		stop

command /sprawdzanie-miejsce [<text>]:
	permission: sprawdanie.miejsce
	permission message: Nie masz permisji!
	trigger:
		set {bSprawdzanie::lokacjaSprawdzania} to location of player
		send "Poprawnie ustawiles lokacje sprawdzania!"
		stop
		
on quit:
	if {bSprawdzanie::statusSprawdzania::%player%} is not set:
		stop
	set {_sprawdzajacy} to {bSprawdzanie::statusSprawdzania::%player%}

	ban player due to "Wylogowanie sie podczas sprawdzania!" for 14 days
	send "Gracz %player% wyszedl podczas sprawdzania!" to {_sprawdzajacy}
	#send "Gracz %player% wylogowal sie podczas sprawdzania!" to all players

	clear {bSprawdzanie::statusSprawdzania::%player%}
	clear {bSprawdzanie::statusSprawdzania::%{_sprawdzajacy}%}

Nie testowałem, mogły się natrafić błędy.
Nie zwracaj uwagi na błędy związane z teleportem na spawna - (lokacja spawna) musisz podmienić na albo koordynaty swojego spawna, albo zmienną, w której je przechowujesz.