Skrypt na odwiedzanie

command /odwiedz [<text>]:
	trigger:
		if arg 1 is not set:
			send "/odwiedz <nick> - odzwiedza wybranego gracza"
			stop
		if {wyspa::%arg 1%} is set:
			if {wyspa::%arg 1%::alwaysAccept} is not set:
				#Tutaj mozesz se dodac cooldown teleportu
				teleport player to {wyspa::%arg 1%}
				send "Pomyslnie przeteleportowalo."
				stop
			set {_arg} to arg 1 parsed as offlineplayer
			if {_arg} is online:
				if {wyspa::%arg 1%::attempt} is set:
					if {wyspa::%arg 1%::attempt::delay} is larger than now:
						send "Gracz ma juz zaproszenie, poczekaj chwile."
						stop
				send "Gracz %player% chce odwiedzic twoja wyspe. %nl%Napisz &7/wyspa tak &rby potwierdzic.%nl%Napisz &7/wyspa nie &raby odrzucic." to {_arg}
				set {wyspa::%arg 1%::attempt} to player
				set {wyspa::%arg 1%::attempt::delay} to now
				add 15 seconds to {wyspa::%arg 1%::attempt::delay}
				stop
			send "Gracza nie ma na serwerze."
			stop
		send "Gracz nie ma punktu teleportu."
command /wyspa [<text>] [<text>]:
	trigger:
		if arg 1 is not set:
			send "/wyspa ustaw odwiedz &7Ustawia punkt teleportu dla graczy odwiedzajacych"
			send "/wyspa zawszeakceptuj <tak/nie> &7gracze moga odwiedzac bez akceptacji lub tylko wylacznie z nia"
			stop
		if arg 1 is "ustaw":
			if arg 2 is "odwiedz":
				set {wyspa::%player%} to location of player
				send "Ustawiono lokalizacje."
				stop
		if arg 1 is "zawszeakceptuj":
			if arg 2 is "tak":
				clear {wyspa::%player%::alwaysAccept}
				send "Ustawiles na: &7Zawsze zaakceptowane."
				stop
			if arg 2 is "nie":
				set {wyspa::%player%::alwaysAccept} to false
				send "Ustawiles na: &7Potrzeba akceptacji."
				stop
		if arg 1 is "tak":
			if {wyspa::%player%::attempt} is set:
				if {wyspa::%player%::attempt::delay} is larger than now:
					teleport {wyspa::%player%::attempt} to {wyspa::%player%}
					send "Pomyslnie przeteleportowano" to {wyspa::%player%::attempt}
					clear {wyspa::%player%::attempt::delay} and {wyspa::%player%::attempt}
					stop
				clear {wyspa::%player%::attempt::delay} and {wyspa::%player%::attempt}
				send "Zaproszenie wygaslo."
				stop
			send "Nie masz zadnego zaproszenia."
			stop
		if arg 1 is "nie":
			if {wyspa::%player%::attempt} is set:
				send "Gracz %player% odrzucil twoja prosbe." to {wyspa::%player%::attempt}
				clear {wyspa::%player%::attempt::delay} and {wyspa::%player%::attempt}
				send "Zaproszenie anulowane."
				stop
			send "Nie masz zadnego zaproszenia."
			stop