Kupowanie permisji w gui (na nick)

options:
	file: "../../BuyPermission/config.yml"
	guiName: &lPermissions
on script load:
	clear {buypermission.error}
	if "%yaml value ""created"" from "{@file}"%" is "<none>":
		set yaml value "created" from {@file} to true
		set yaml value "buypermission.test.permission" from {@file} to "essentials.fly"
		set yaml value "buypermission.test.prize" from {@file} to "2000"
		set yaml value "buypermission.dwa.permission" from {@file} to "skript.admin"
		set yaml value "buypermission.dwa.prize" from {@file} to "300"
	send "Sprawdzam poprawnosc configu buypermission..." to console
	set {_permissions::*} to yaml nodes "buypermission" from {@file}
	loop {_permissions::*}:
		set {_x} to yaml value "buypermission.%loop-value%.prize" from {@file}
		set {_x} to {_x} parsed as integer
		if {_x} is not integer:
			send "Znalazlem blad: buypermission.%loop-value%.prize nie jest liczba!" to console
			set {_err} to true
	if {_err} is true:
		set {buypermission.error} to true
command /test:
	trigger:
		if {buypermission.error} is not set:
			set {_permissions::*} to yaml nodes "buypermission" from {@file}
			if size of {_permissions::*} is larger than 0:
				set {_rows} to ceil("%size of {_permissions::*}%" parsed as integer / 9)
				open chest with {_rows} rows named "{@guiName}" to player
				set {_gn} to {_rows}*9-1
				wait 2 tick
				loop {_permissions::*}:
					set {_permission} to yaml value "buypermission.%loop-value%.permission" from {@file}
					set {_prize} to yaml value "buypermission.%loop-value%.prize" from {@file}
					if player has permission "%{_permission}%":
						set {_z} to "&aPosiadasz"
					else:
						set {_z} to "&cNie posiadasz"
					set player's current inventory's slot loop-index parsed as integer - 1 to paper named "&a&l$%{_prize}%" with lore "&cPermisja:||&3%{_permission}%||||%{_z}%"
				set player's current inventory's slot {_gn} to gold nugget named "&cStan konta" with lore "&cPosiadasz:||&a  %player's balance%"
				stop
			send "&cNie ma zadnych permissi w configu."
			stop
		send "&cBledna konfiguracja buypermission."
		stop
on inventory click:
	if "%inventory name of player's current inventory%" is "{@guiName}":
		if slot is smaller than 0:
			stop
		cancel event
		if player's current inventory's slot slot is paper:
			set {_lore::*} to uncoloured lore of player's current inventory's slot slot split at "||"
			if "%{_lore::4}%" is "Nie posiadasz":
				set {_prize} to "%uncoloured name of player's current inventory's slot slot%"
				replace all "$" with "" in {_prize}
				set {_prize} to {_prize} parsed as integer
				send "%{_prize}%"
				if player's balance is larger than or equal to {_prize}:
					remove {_prize} from player's balance
					execute console command "pex user %player% add %{_lore::2}%"
					send "&c* &7Zakupiles permissie: %{_lore::2}%"
					close player's inventory
					stop
				send "&cBrakuje tobie: &a$%{_prize} - player's balance%"
				stop
			send "&cJuz posiadasz te permissie."
			stop
		stop