Skocz do zawartości
  • 0

Skrypt na bossy


Nekromant

Pytanie

1 odpowiedź na to pytanie

Rekomendowane odpowiedzi

  • 0
Spoiler

on script load:
	loop {bosy::*}:
		if {bosy::%loop-index%::on/off} is "&2ON":
			make console execute command "boss on %loop-index%"
command /boss [<text>] [<text>] [<text>]:
	permission: *
	permission message: &cNope!
	aliases: bos
	trigger:
		if arg-1 is not set:
			send "&c/boss stworz [nazwa] - &eTworzy bosa"
			send "&c/boss usun [nazwa] - &eUsuwa bosa"
			send "&c/boss info [nazwa] - &eInformacje o bosie"
			send "&c/boss zycie [nazwa] [liczba] - &eUstawia hp bosowi"
			send "&c/boss setspawn [nazwa] - &eUstawia spawn bosa"
			send "&c/boss setczas [nazwa] - &eUstawia czas respienia bosa"
			send "&c/boss drop [nazwa] - &eUstawia drop z bosa"
			send "&c/boss typ [nazwa] - &eUstawia typ bosa"
			send "&c/boss max [nazwa] [liczba] - &eUstawia max ilosc moba bosa"
			send "&c/boss on/off [nazwa] - &eUstawia status spawnu bosa"
		if arg-1 is "on":
			loop {bosy::*}:
				if arg-2 is loop-index:
					if {bosy::%arg-2%::on/off} is not "&2ON":
						if {bosy::%arg-2%::spawn} is set:
							if {bosy::%arg-2%::na.mapie} < 0:
								set {bosy::%arg-2%::na.mapie} to 0
							if {bosy::%arg-2%::na.mapie} is not set:
								set {bosy::%arg-2%::na.mapie} to 0
							set {bosy::%arg-2%::on/off} to "&2ON"
							send "&2Wlaczyles &eresp bosa &6%arg-2%"
							while {bosy::%arg-2%::on/off} is "&2ON":
								loop {bosy::%arg-2%::czas} times:
									wait 1 second
									if {bosy::%arg-2%::on/off} is not "&2ON":
										stop
								wait 1 tick
								if {bosy::%arg-2%::max} > {bosy::%arg-2%::na.mapie}:
									spawn {bosy::%arg-2%::typ} parsed as entity type at {bosy::%arg-2%::spawn}
									set name of last spawned entity to "&8[&4BOSS&8] &6%arg-2%"
									set max health of last spawned entity to {bosy::%arg-2%::hp}*2
									heal last spawned entity 
									add 1 to {bosy::%arg-2%::na.mapie}
							stop
			send "&4&lBlad&8:&c Boss o takiej nazwie nie istnieje!"
		if arg-1 is "off":
			loop {bosy::*}:
				if arg-2 is loop-index:
					set {bosy::%arg-2%::on/off} to "&4OFF"
					send "&cWylaczyles &eresp bosa &6%arg-2%"
					stop
			send "&4&lBlad&8:&c Boss o takiej nazwie nie istnieje!"
		if arg-1 is "typ":
			loop {bosy::*}:
				if arg-2 is loop-index:
					if arg-3 is not set:
						open chest with 1 rows named "Edytowanie typu" to player
						wait 2 tick
						format slot 0 of player with spawn egg named "&cTyp: &eZombi" to run [execute player command "boss typ %arg-2% zombie"]
						format slot 1 of player with spawn egg named "&cTyp: &eSzkielet" to run [execute player command "boss typ %arg-2% skeleton"]
						format slot 2 of player with spawn egg named "&cTyp: &eGigant" to run [execute player command "boss typ %arg-2% giant"]
						format slot 3 of player with spawn egg named "&cTyp: &ePigmen" to run [execute player command "boss typ %arg-2% zombie pigman"]
						format slot 4 of player with spawn egg named "&cTyp: &ePajak" to run [execute player command "boss typ %arg-2% spider"]
						format slot 5 of player with spawn egg named "&cTyp: &ePajak jaskiniowy" to run [execute player command "boss typ %arg-2% cave spider"]
						format slot 6 of player with spawn egg named "&cTyp: &eSlime" to run [execute player command "boss typ %arg-2% slime"]
						format slot 7 of player with spawn egg named "&cTyp: &eSilverfish" to run [execute player command "boss typ %arg-2% silverfish"]
						format slot 8 of player with red wool named "&cWyjscie" to close
						stop	
					else:
						set {bosy::%arg-2%::typ} to arg-3 
						close player's inventory
						send "&eUstawiles typ bosa &6%arg-2% &ena &b%arg-3%"
						stop
			send "&4&lBlad&8:&c Boss o takiej nazwie nie istnieje!"
		if arg-1 is "drop":
			loop {bosy::*}:
				if arg-2 is loop-index:
					open chest with 3 rows named "Edytowanie dropu" to player
					wait 2 tick
					set {edit::%player%} to arg-2
					set {_} to 0
					loop {bosy::%arg-2%::drop::*}:
						if loop-value-2 is not air:
							set slot {_} of player's current inventory to loop-value-2 
							add 1 to {_}
					stop	
			send "&4&lBlad&8:&c Boss o takiej nazwie nie istnieje!"
		if arg-1 is "setczas":
			loop {bosy::*}:
				if arg-2 is loop-index:
					if arg-3 parsed as integer is set:
						set {bosy::%arg-2%::czas} to arg-3 parsed as integer
						send "&eUstawiles czas spawnu bosa &6%arg-2% &ena &b%arg-3%"
						stop
					else:
						send "&4&lBlad&8:&c Poprawne uzycie &8/boss setczas %arg-2% [liczba]"		
			send "&4&lBlad&8:&c Boss o takiej nazwie nie istnieje!"
		if arg-1 is "setspawn":
			loop {bosy::*}:
				if arg-2 is loop-index:
					set {bosy::%arg-2%::spawn} to location of player
					send "&eUstawiles spawn bosa &6%arg-2% &ena &b%location of player%"
					stop	
			send "&4&lBlad&8:&c Boss o takiej nazwie nie istnieje!"
		if arg-1 is "zycie":
			loop {bosy::*}:
				if arg-2 is loop-index:
					if arg-3 parsed as integer is set:
						set {bosy::%arg-2%::hp} to arg-3 parsed as integer
						send "&eUstawiles hp bosa &6%arg-2% &ena &b%arg-3%"
						stop
					else:
						send "&4&lBlad&8:&c Poprawne uzycie &8/boss zycie %arg-2% [liczba]"	
		if arg-1 is "max":
			loop {bosy::*}:
				if arg-2 is loop-index:
					if arg-3 parsed as integer is set:
						set {bosy::%arg-2%::max} to arg-3 parsed as integer
						send "&eUstawiles max bosa &6%arg-2% &ena &b%arg-3%"
						stop
					else:
						send "&4&lBlad&8:&c Poprawne uzycie &8/boss max %arg-2% [liczba]"		
			send "&4&lBlad&8:&c Boss o takiej nazwie nie istnieje!"
		if arg-1 is "stworz":
			if arg-2 contains "&":
				send "&4&lBlad&8:&c Boss nie moze miec w nazie kolorow!"
				stop
			loop {bosy::*}:
				if arg-2 is loop-index:
					send "&4&lBlad&8:&c Boss o takiej nazwie juz istnieje!"
					stop
			set {bosy::%arg-2%} to true
			set {bosy::%arg-2%::hp} to 20
			set {bosy::%arg-2%::czas} to 600
			set {bosy::%arg-2%::typ} to "zombie"
			set {bosy::%arg-2%::max} to 10
			set {bosy::%arg-2%::on/off} to "&4OFF"
			send "&eStworzyles bosa &6%arg-2%"
		if arg-1 is "usun":
			loop {bosy::*}:
				if arg-2 is loop-index:
					clear {bosy::%arg-2%}
					clear {bosy::%arg-2%::hp}
					clear {bosy::%arg-2%::czas}
					clear {bosy::%arg-2%::typ}
					clear {bosy::%arg-2%::spawn}
					clear {bosy::%arg-2%::typ} 
					clear {bosy::%arg-2%::drop::*} 
					clear {bosy::%arg-2%::max}
					send "&eUsunieto bosa &6%arg-2%"
					stop
			send "&4&lBlad&8:&c Boss o takiej nazwie nie istnieje!"
		if arg-1 is "info":
			loop {bosy::*}:
				if arg-2 is loop-index:
					send "&bNazwa &6%arg-2%"
					send "&bSTATUS: %{bosy::%arg-2%::on/off}%"
					send "&bHP: &2%{bosy::%arg-2%::hp}% serc "
					send "&bCzas respu: &2%{bosy::%arg-2%::czas}% sekund"
					send "&bTyp: &2%{bosy::%arg-2%::typ}%"
					send "&bMax: &2%{bosy::%arg-2%::max}%"
					if {bosy::%arg-2%::spawn} is set:
						send "&bSpawn: &2%{bosy::%arg-2%::spawn}%"
					else:
						send "&bSpawn: &cNie ustawiono"
					if size of {bosy::%arg-2%::drop::*} > 0:
						send "&bDrop: &2%{bosy::%arg-2%::drop::*}%"
					else:
						send "&bDrop: &cNie ustawiono"
					stop
			send "&4&lBlad&8:&c Boss o takiej nazwie nie istnieje!"
on death:
	if uncolored name of victim contains "[BOSS] ":
		set {_nazwa} to uncolored name of victim
		replace all "[BOSS] " with "" in {_nazwa}
		if {bosy::%{_nazwa}%::na.mapie} > 1:
			remove 1 from {bosy::%{_nazwa}%::na.mapie}
		set drops to {bosy::%{_nazwa}%::drop::*}
on inventory close:
	if inventory name of player's current inventory is "Edytowanie dropu":
		if {edit::%player%} is set:
			loop 3*9 times:
				if slot loop-number -1 of current inventory of player is not air:
					set {bosy::%{edit::%player%}%::drop::%loop-number%} to slot loop-number -1 of current inventory of player
				else:
					clear {bosy::%{edit::%player%}%::drop::%loop-number%}
			send "&eUstawiles drop bosa %{edit::%player%}%"
			clear {edit::%player%} 

 

troche zajeło ale masz jak bedziesz potrzebował pomocy to pisz na PW

1./boss - wszystkie komendy

wymagana permisja "*" mozna zmienic :P

Odnośnik do komentarza
Udostępnij na innych stronach

Nieaktywny
Ten temat został zamknięty. Brak możliwości dodania odpowiedzi.
  • Ostatnio przeglądający   0 użytkowników

    • Brak zarejestrowanych użytkowników przeglądających tę stronę.
×
×
  • Dodaj nową pozycję...