Utworzenie skryptu na włączenie TNT w okreslonych godzinach

Ziomek co ty odwaliłeś xD 

Options:
	
	godz.wl: 12
	godz.wyl: 22

on join:
	if player is op:
		if {TNT} is not set:
			set {TNT} to "&4wylaczone"

every 1 hour:
	set {_godz} to hour
	if {_godz} is {@godz.wyl}:
		set {TNT} to "&4wylaczone"
		broadcast "&7Wybila godzina {@godz.wyl}! TNT zostalo: %{TNT}%&7!"
	else if {_godz} is {@godz.wl}:
		set {TNT} to "&2wlaczone"
		broadcast "&7Wybila godzina {@godz.wl}! TNT zostalo: %{TNT}%&7!"

on place of tnt:
	if {tnt} is "&4wylaczone":
		cancel event
		send "&7TNT jest: %{TNT}%&7!"

command /tnt:
	trigger:
		send "&7TNT jest: %{TNT}%"

Tak btw. "trigger" stosujemy przy evencie komendy, optionsy to są opcje (xD), po każdym sprawdzeniu (if ...) musi być znak ":".

#Autor: Shooterowy

options:
	time_on: 8
	time_off: 20
variables:
	{TNT::status} = 2
on place of TNT:
	if player doesn't have the permission "TNT.*" or "TNT.bypass":
		if {TNT::status} is 0:
			cancel event
			send "&cTNT jest aktualnie wylaczone przez administratora."
			stop
		if {TNT::status} is 2:
			if hour is smaller than {@time_on}:
				cancel event
				send "&7TNT jest wlaczone w godzinach od &c{@time_on} &7do &c{@time_off}&c."
				stop
			if hour is more than or equal to {@time_off}:
				cancel event
				send "&7TNT jest wlaczone w godzinach od &c{@time_on} &7do &c{@time_off}&c."
				stop
command /tnt [<text>]:
	trigger:
		if arg is not set:
			if {TNT::status} is 0:
				send "&cTNT jest aktualnie wylaczone przez administratora."
				stop
			if {TNT::status} is 1:
				send "&aTNT jest aktualnie wlaczone przez administratora."
				stop
			if {TNT::status} is 2:
				send "&7TNT jest wlaczone w godzinach od &c{@time_on} &7do &c{@time_off}&c."
				if hour is smaller than {@time_on}:
					send "&cTNT jest aktualnie wylaczone."
					stop
				if hour is more than or equal to {@time_off}:
					send "&cTNT jest aktualnie wylaczone."
					stop
				send "&aTNT jest aktualnie wlaczone."
				stop
		if arg is not "wlacz" or "on" or "wylacz" or "off" or "auto":
			execute player command "tnt"
			stop
		if player doesn't have the permission "TNT.*":
			send "&cNie masz uprawnien do tej komendy!"
			stop
		if arg is "wlacz" or "on":
			set {TNT::status} to 1
			send "&aWlaczyles TNT."
			stop
		if arg is "wylacz" or "off":
			set {TNT::status} to 0
			send "&cWylaczyles TNT."
			stop
		if arg is "auto":
			set {TNT::status} to 2
			send "&7Ustawiles TNT na tryb automatyczny."
			stop

Łap, może Ci się przyda.