Turbek z anarchia.gg boxpvp albo podobny

options:
	nazwaIronGolem: "&a&lTurbek"
	odlamek: gray dye of mending 1 named "&4Anarchiczne serce"
	czas: 10 minutes
on script load:
	if {turbek::odlamki} is not set:
		set {turbek::lastActive} to "Brak"
		set {turbek::lastPayer} to "Brak"
		set {turbek::odlamki} to 0
command /dodajturbek:
	trigger:
		if sender is player:
			if player has permission "turbek.dodaj":
				spawn iron golem at the player
				set name of last spawned entity to {@nazwaIronGolem}
				apply glowing to last spawned entity for 999 days
				stop
			send "Nie masz uprawnien"
			stop
		send "Komenda nie dla konsoli"
		stop
on damage:
	if victim is iron golem:
		if name of victim is {@nazwaIronGolem}:
			cancel event
on rightclick on iron golem:
	if name of clicked entity is {@nazwaIronGolem}:
		set {_x} to chest with 1 rows named {@nazwaIronGolem}
		set {_lore::1} to "&7Aktywujac ten &aEVENT &7caly serwer"
		set {_lore::2} to "&7otrzyma efekt &4&lSiŁa II &7na {@czas}"
		set {_lore::3} to " "
		set {_lore::4} to "&7ostatnio aktywowany %{turbek::lastActive}%"
		set {_lore::5} to "&1ostatnio wplacajacy odlamki %{turbek::lastPayer}%"
		set {_lore::6} to "&4Odłamki (%{turbek::odlamki}%/200)"
		
		set {_potion} to potion of mundane named "&5SILA II DLA SERWERA" with lore {_lore::*}
		set {_str} to potion effect of strength of tier 2 for {@czas}
		add {_str} to potion effects of {_potion}
		set slot 4 of {_x} to {_potion}
		open {_x} to player
on inventory click:
	if inventory name of player's current inventory is {@nazwaIronGolem}:
		cancel event
		if clicked slot is 4:
			if player has 1 of {@odlamek}:
				if {turbek::active} is true:
					if {turbek::odlamki} is larger than 190:
						send "Wplacanie zostalo wstrzymane, gdyz trwa event i zostalo za duzo wplacone na nowy event"
						stop
				remove 1 of {@odlamek} from player
				add 1 to {turbek::odlamki}
				set {turbek::lastPayer} to name of player
				if {turbek::odlamki} is larger than or equal to 200:
					broadcast "Zaczal sie event turbo sily!"
					loop all players:
						remove strength from loop-player
					set {turbek::odlamki} to 0
					set {turbek::active} to true
					set {turbek::lastActive} to now
				loop all players:
					if inventory name of loop-player's current inventory is {@nazwaIronGolem}:
						set line 5 of lore of slot 4 of loop-player's current inventory to "&1ostatnio wplacajacy odlamki %{turbek::lastPayer}%"
						set line 6 of lore of slot 4 of loop-player's current inventory to "&4Odłamki (%{turbek::odlamki}%/200)"
				stop
			send "Nie posiadasz odlamka"
			stop
on respawn:
	if {turbek::active} is true:
		set {turbek::active::%player%} to true
on join:
	#Nie wiem jak to wplywa na pluginy z logowaniem.
	if {turbek::active::%player%} is set:
		if {turbek::active} is not set:
			remove strength from player
			clear {turbek::active::%player%}
			stop
		if {turbek::active::%player%} is not true:
			remove strength from player
			wait 1 tick
			set {_applyTime} to {@czas}
			remove difference between {turbek::lastActive} and now from {_applyTime}
			apply potion of strength 2 to player for {_applyTime}
#Aby zmniejszyc lagi jezeli gra powyzej 50-100 osob zwieksz every 2 seconds na every 5 seconds lub wiecej.
every 2 seconds:
	if {turbek::active} is true:
		set {_time} to difference between {turbek::lastActive} and now
		if {_time} is smaller than {@czas}:
			loop all players:
				if loop-player doesn't have potion effect strength:
					if {turbek::active::%loop-player%} is not true:
						set {_applyTime} to {@czas}
						remove {_time} from {_applyTime}
						apply potion of strength 2 to loop-player for {_applyTime}
						set {turbek::active::%loop-player%} to {_applyTime}
		else:
			broadcast "Event sie zakonczyl"
			clear {turbek::active}