TNT Bez Griefu

Ten temat został przeniesiony.

Jak zostal przeniesiony? Nie rozumiem. Nie mozesz napisac skryptu?

8 godzin temu, Sergio_YT123 napisał:

Jak zostal przeniesiony? Nie rozumiem. Nie mozesz napisac skryptu?

Przeniosłem ten temat, ponieważ utworzył go Pan w dziale "Skript > Pytania i problemy", a jest to zlecenie.

19 godzin temu, Sergio_YT123 napisał:

Czesc, ma ktos skrypt na tnt ktore po wpisaniu komendy wybucha i wyrzuca gracza tak jak na bedwarsach, i nie griefuje, a takze nie zadaje HP.

Proszę bardzo. Skrypt był testowany.

Na górze skryptu może Pan modyfikować zasięg odrzutu TNT (to znaczy w jakim promieniu od TNT należy stać, aby zostać odrzuconym) i siłę (wzmocnienie) odrzutu.

options:
	maxExplosionRange: 3
	knockbackAmplification: 3
	
function constantToVector(n: number) :: vector:
	return vector({_n}, {_n}, {_n})
		
command /bankatnt:
	executable by: players
	permission: deskcraft.perm.tnt
	permission message: &6Nie posiadasz wystarczających uprawnień do wykonania tej komendy.
	trigger:
		spawn tnt at player:
			set explosive yield of event-entity to 0
			set metadata tag "harmlessNoGriefTNT" of event-entity to true

on explosion:
	event is not cancelled
	metadata tag "harmlessNoGriefTNT" of event-entity is true
	loop all living entities in radius {@maxExplosionRange} around event-entity:
		set {_dirV} to vector from event-entity to loop-entity
		set {_maxV} to constantToVector({@knockbackAmplification}) * (normalized {_dirV})
		push loop-entity ({_maxV} - {_dirV})

Opcjonalnie, może Pan sprawdzić czy w przypadku zamiany przedostatniej linijki ('set {_maxV} to...') na poniższą skrypt nadal będzie działał i da mi znać. Jeśli zadziała, może Pan usunąć całą funkcję 'constantToVector' ze skryptu, ponieważ będzie ona już niepotrzebna.

Z góry dziękuję za chęci.

set {_maxV} to {@knockbackAmplification} * (normalized {_dirV})

Pozdrawiam.

Dziala, ale mozna zespawnowac je bez cooldownu, czyli odrazu wybucha?

Godzinę temu, Sergio_YT123 napisał:

Dziala, ale mozna zespawnowac je bez cooldownu, czyli odrazu wybucha?

Nie ma problemu. Proszę.

Dodałem na górze skryptu możliwość konfigurowania czasu (w tickach) przed eksplozją po pojawieniu się TNT. Do działania skryptu wymagany jest dodatek skript-reflect, ponieważ Skript nie oferuje możliwości zmiany czasu oczekiwania na eksplozję.

options:
	maxExplosionRange: 3
	knockbackAmplification: 3
	ticksUntilExplosion: 10
	
function constantToVector(n: number) :: vector:
	return vector({_n}, {_n}, {_n})
		
command /bankatnt:
	executable by: players
	permission: deskcraft.perm.tnt
	permission message: &6Nie posiadasz wystarczających uprawnień do wykonania tej komendy.
	trigger:
		spawn tnt at player:
			set explosive yield of event-entity to 0
			event-entity.setFuseTicks({@ticksUntilExplosion})
			set metadata tag "harmlessNoGriefTNT" of event-entity to true

on explosion:
	event is not cancelled
	metadata tag "harmlessNoGriefTNT" of event-entity is true
	loop all living entities in radius {@maxExplosionRange} around event-entity:
		set {_dirV} to vector from event-entity to loop-entity
		set {_maxV} to constantToVector({@knockbackAmplification}) * (normalized {_dirV})
		push loop-entity ({_maxV} - {_dirV})

Tak z ciekawości. Czy sprawdził Pan to o co pytałem? O tym mówię:

2 godziny temu, Kormic napisał:

Opcjonalnie, może Pan sprawdzić czy w przypadku zamiany przedostatniej linijki ('set {_maxV} to...') na poniższą skrypt nadal będzie działał i da mi znać. Jeśli zadziała, może Pan usunąć całą funkcję 'constantToVector' ze skryptu, ponieważ będzie ona już niepotrzebna.

Z góry dziękuję za chęci.

set {_maxV} to {@knockbackAmplification} * (normalized {_dirV})

Pozdrawiam.

linijka 16: Can't understand this condition/effect

7 godzin temu, Sergio_YT123 napisał:

linijka 16: Can't understand this condition/effect

Czy Pan przeczytał to co napisałem? Jeśli tak, proszę podać wersję serwera, Skripta i dodatku skript-reflect.

Oj, przepraszam, bylem skupiony na kopiowaniu skryptu, i nie zauwarzylem.  sprawdze pozniej, i dam znac

Pozdrawiam