Potrzebuję skryptu.

4 minuty temu, Kormic napisał:

Proszę zauważyć, że w moich skryptach wklejam sekcję import zawsze nad wszelkim kodem, aby Skript w pierwszej kolejności pobrał z innych API wszystkie potrzebne rzeczy.

Sam autor skript-reflect zaleca tak czynić, więcej o tym można poczytać tutaj.

Niemniej jednak dobrze, że się to wyjaśniło. Niech Pan jeszcze raz przejrzy wszystko to o czym pisałem i da znać czy działa jak należy.

Wszystko działa perfekcyjnie, lecz potrzebowałbym jeszcze skrypta na to, że jeśli gracz umrze w regionie "event-wakacyjny" to nie straci swoich przedmiotów, lecz jeśli nie ma permisji "wakacje.drop1" to traci 50% swoich rozgwiazd, lecz jeśli gracz będzie miał permisję "wakacje.drop1", to nie straci ani przedmiotów, ani rozgwiazd, oraz aby w regionie "event-wakacyjny" nie można byłoby zakładać elytry, bo wyświetlal by się subtitle "&cNie możesz tutaj zakładać elytry!"

46 minut temu, Jowiszek napisał:

Wszystko działa perfekcyjnie

Miło mi to słyszeć.

46 minut temu, Jowiszek napisał:

potrzebowałbym jeszcze skrypta na to, że jeśli gracz umrze w regionie "event-wakacyjny" to nie straci swoich przedmiotów, lecz jeśli nie ma permisji "wakacje.drop1" to traci 50% swoich rozgwiazd, lecz jeśli gracz będzie miał permisję "wakacje.drop1", to nie straci ani przedmiotów, ani rozgwiazd

Proszę uprzejmie. Wydaje mi się, że o to Panu chodziło.

options:
	worldName: world
	
function hornCoralPlantsReduce(p: player):
	{hornCoralPlants::removeFifty::%uuid of {_p}%} is set
	set {_item} to living horn coral plant named "&6Rozgwiazda" with lore "&8» &7Waluta z &eEventu wakacyjnego &f(2024)" and "&8» &7Wymienisz ją na &fklucze &7pod &f/event"
	set {_number} to amount of {_item} in {_p}'s inventory
	{_number} > 0
	set {_reducedNumber} to ceil({_number} / 2)
	remove {_reducedNumber} of {_item} from {_p}'s inventory
	clear {hornCoralPlants::removeFifty::%uuid of {_p}%}
	
on death of player:
	"%regions at event-location%" contains "event-wakacyjny in world {@worldName}"
	keep inventory
	victim doesn't have permission "wakacje.drop1"
	set {hornCoralPlants::removeFifty::%uuid of victim%} to true
	
on respawn:
	hornCoralPlantsReduce(player)
	
on join:
	hornCoralPlantsReduce(player)

48 minut temu, Jowiszek napisał:

oraz aby w regionie "event-wakacyjny" nie można byłoby zakładać elytry, bo wyświetlal by się subtitle "&cNie możesz tutaj zakładać elytry!"

Tutaj proponuję Panu zainteresowanie się pluginem WorldGuard Extra Flags. Po jego zainstalowaniu może Pan ustawić dla tego regionu blokadę latania przy pomocy elytry.

Co prawda można to zablokować w Skript, ale jeśli plugin już to oferuje, lepiej wybrać takie rozwiązanie.