Jak zrobić skryptem aby jesli naprzyklad ktos postawi jakis blok to ktos inny nie bedzie bogl go zniszczyc

Zapisz go do zmiennej podczas stawiania.

Jeśli inny gracz w evencie on break będzie próbował go zniszczyć - anuluj event.

a dasz przyklad?

Do której części potrzebujesz przykład?
 

on place:
    if player has permission "OwnBlocks.use":
        set {ownerOfBlock::%event-block's location%} to player

on break:
    if {ownerOfBlock::%event-block's location%} is set:
        if {ownerOfBlock::%event-block's location%} is not player:
            if player does not have permission "OwnBlocks.ignoreOwnership":
                cancel event
                send "&cTen blok należy do %{ownerOfBlock::%event-block's location%}%."
            else:
                delete {ownerOfBlock::%event-block's location%}
    else:
        delete {ownerOfBlock::%event-block's location%}

command /ownblocks <text>:
    trigger:
        if arg-1 is set:
            if arg-1 is "info":
                if player has permission "OwnBlocks.info":
                    send "&aTen blok należy do %{ownerOfBlock::%location of target block of player%}%."
                else:
                    send "&cNie masz uprawnień do użycia tej komendy."
            else if arg-1 is "add":
                if player has permission "OwnBlocks.add":
                    set {ownerOfBlock::%location of target block of player%} to player
                    send "&aDodano ochronę!"
                else:
                    send "&cNie masz uprawnień do użycia tej komendy."
            else if arg-1 is "delete":
                if player has permission "OwnBlocks.delete":
                    delete {ownerOfBlock::%location of target block of player%}
                    send "&aUsunięto ochronę!"
                else:
                    send "&cNie masz uprawnień do użycia tej komendy."
            else:
                send "&cNieprawidłowa komenda."