Skrypt na przyciągająca wędkę (hak Batmana)

.

Godzinę temu, Nicki napisał:

no pomoze ktos??

Słuchaj no, jesteś bardzo wymagający i na dodatek jeszcze się wkurzasz (tak wnioskuje po tym komentarzu) na o, że nikt ci nie pomaga. Jeżeli potrzebujesz tego skryptu to polecam zgłosić się do kogoś kto robi skrypty za pieniądze (np. coffein) oni z pewnością zrobią to o co prosisz (oczywiscie za oplatą). Inaczej musisz czekac a moze ci ktos taki skrypt napisze :).

Dzięki za radę :). Poczekam aż znajdzie się jakas osoba która da radę to zrobic :>. Nie zalezy mi na czasie

Hej Nicki Mam Skript na to tylko 
1.bez tota
2.troche nie twoje wymagania
Skript mam nadzieje ze ci sie spodoba troche sie napracowalem milego!


SKRIPT:



-----------------------------------------------------------------------------------------------------------


 

on fish:
    if fishing state is reel in:
        if unformatted name of player's tool is "Hak Batmana (Kliknij Prawy Przycisk)":
            if lore of player's tool contains "&8To Hak Batmana Jest on unikalny!":
                if {grapple::cooldown::%player's uuid%} isn't set:
                    set {grapple::falldamage::%player's uuid%} to true
                    push player upwards at speed 1
                    push player forwards at speed 2
                    damage player's tool by 2
                    set {grapple::cooldown::%player's uuid%} to 5 seconds from now
                    wait 5 seconds
                    delete {grapple::cooldown::%player's uuid%}
                    delete {grapple::falldamage::%player's uuid%}
                else if {grapple::cooldown::%player's uuid%} is set:
                    send "&cNastępne użycie możesz wykonać za. &7(%difference between now and {grapple::cooldown::%player's uuid%}%)" to player
                    set {_item} to player's tool
                    set player's tool to air
                    set player's tool to {_item}

on swap hand item:
    if unformatted name of player's tool is "Hak Batmana (Kliknij Prawy Przycisk)":
        if lore of player's tool contains "&8To Hak Batmana Jest on unikalny!":
            cancel event
            send "%nl%&cUwaga! Nie można Używać tego Itemu w 2 łapce!%nl%"

command /dajhakbatmana [<text>]:
    permission: Dawido.Hakbatmana
    permission message: &4&lERROR ---> &c&lNie Masz Permisji! &7(Dawido.Hakbatmana)
    trigger:
        give fishing rod of unbreaking 9 named "&6Hak Batmana &7(&eKliknij Prawy Przycisk&7)" with lore "&8To Hak Batmana Jest on unikalny!" to player

on damage:
    if "%damage cause%" is "fall":
        if {grapple::cooldown::%victim's uuid%} is set:
            cancel event

on enchant prepare:
    if event-item is fishing rod:
        if lore of event-item contains "&8To Hak Batmana Jest on unikalny!":
            set enchant offer 1, 2 and 3 to thorns 1
            set the cost of enchant offer 1, 2 and 3 to 100000

on anvil prepare:
    if lore of slot 0 of event-inventory contains "&8To Hak Batmana Jest on unikalny!":
        set repair cost of event-inventory to -1

słuchaj taką samą "wędkę batmana" możesz zrobić z pluginem GetCustomItem masz tam mnóstwo innych customowych przedmiotów ale możesz mieć też tą Wędkę batmana pod komendą /getcustomitem give (nick) hook (liczba ile chcesz tych wędek)

@dawid125439 oraz @czaro

Bardzo dziękuje za poardy! Problem rozwiązany