Skrypt na kody

Proszę bardzo

command /utworzkod [<text>] [<text>] [<text>]:
	permission: utworz.kod
	permission message: &cNie masz uprawnień do tej komendy.
	trigger:
		if arg 1 is not set:
			send "&cPoprawne użycie: /utworzkod <kod> <ilość użyć> <komenda>"
			send "&7Jeżeli chcesz, aby komenda była wykonana przez konsolę, nie dodawaj do niej znaku '/'."
			stop
		if {code::%arg 1%::usages} is set:
			send "&cTaki kod już istnieje."
			stop
		if arg 2 parsed as integer is not set:
			send "&cPoprawne użycie: /utworzkod <kod> <ilość użyć> <komenda>"
			send "&7Jeżeli chcesz, aby komenda była wykonana przez konsolę, nie dodawaj do niej znaku '/'."
			stop
		if arg 3 is not set:
			send "&cPoprawne użycie: /utworzkod <kod> <ilość użyć> <komenda>"
			send "&7Jeżeli chcesz, aby komenda była wykonana przez konsolę, nie dodawaj do niej znaku '/'."
			stop
		set {code::%arg 1%::usages} to arg 2 parsed as integer
		set {code::%arg 1%::command} to arg 3
		send "&aUtworzono kod &e%arg 1% &a(&c%arg 2%&a) z komendą &7%arg 3%&a."
command /odbierz [<text>]:
	permission: odbierz.kod
	permission message: &cNie masz uprawnień do tej komendy.
	trigger:
		if arg is not set:
			send "&cPoprawne użycie: /odbierz <kod>"
			stop
		if {code::%arg%::usages} is not set:
			send "&cTaki kod nie istnieje."
			stop
		if {code::%arg%::usedby::*} contains name of player:
			send "&cUżyłeś już tego kodu"
			stop
		send "&aUżyłeś kodu &e%arg%&a."
		add name of player to {code::%arg%::usedby::*}
		set {_cmd} to {code::%arg%::command}
		replace "{PLAYER}" with "%player%" in {_cmd}
		if {code::%arg%::command} contains "/":
			make player run command "%{_cmd}%" as op
		else:
			execute console command "%{_cmd}%"
		remove 1 from {code::%arg%::usages}
		if {code::%arg%::usages} is 0:
			send "&7Kod &e%arg% &7został wyczerpany." to ops
			clear {code::%arg%::*} and {code::%arg%}

Jeśli chcesz użyć nicku gracza to w komendzie podaj {PLAYER}

Ten temat został zamknięty.