help Skrypt na captha

Godzinę temu, UnioNS napisał:

Witam,

Poszukuje skrypt na wersje 1.16.1, chciałbym aby działał tak że przy wejściu na serwer otwierało się okno (gui) na 27 slotów i we 26 slotach była czerwona wełna a w 1 slocie była zielona wełna (zawsze w losowym miejscu - random number) i jak gracz kliknie w czerwona welne to to wylala z serwera z powodem "x" a jak dobrze kliknie (zielona welne) wyswietla sie komunikat "y" (na srodku ekranu - tittle), jezeli gracz wyłaczy (np kliknie ESC) to okno to pojawia sie znowu, lecz jezeli wylaczy to 3 razy to go tez wywala z powodem "x".

Z góry dziekuje za pomoc.

Proszę, w razie jakichkolwiek błędów daj znać. Jeśli chcesz zmienić jakieś wiadomości, nie zawracaj mi tym głowy, a sam poszukaj ich w kodzie.

EDIT:

Zedytowałem kod. Wymagany Skellett.

function createCaptchaGUI(p: player):
	open chest inventory with 3 rows named "&6&lCaptcha" to {_p}
	loop 27 times:
		set slot loop-number - 1 of {_p}'s current inventory to red wool named "&cKliknij zieloną wełnę!"
	set slot (random integer between 0 and 26) of {_p}'s current inventory to lime wool named "&aKliknij mnie!"

on join:
	wait 1 tick
	if {captcha::iloscZamkniec::%player%} is set:
		clear {captcha::iloscZamkniec::%player%}
	createCaptchaGUI(player)

on inventory click:
	if name of player's current inventory is not "&6&lCaptcha":
		stop
	if clicked inventory is player's inventory:
		stop
	cancel event
	if clicked item is lime wool named "&aKliknij mnie!":
		set {captcha::poprawny::%player%} to true
		close player's inventory
	else if clicked item is red wool named "&cKliknij zieloną wełnę!":
		if {captcha::iloscZamkniec::%player%} is set:
			clear {captcha::iloscZamkniec::%player%}
		if {captcha::iloscZamkniec::%player%} is set:
			clear {captcha::iloscZamkniec::%player%}
		kick player due to "&cNie kliknąłeś zielonej wełny!"
	
on inventory close:
	if name of player's current inventory is not "&6&lCaptcha":
		stop
	if {captcha::poprawny::%player%} is set:
		clear {captcha::poprawny::%player%}
		stop
	add 1 to {captcha::iloscZamkniec::%player%}
	if {captcha::iloscZamkniec::%player%} is less than 3:
		wait 1 tick
		createCaptchaGUI(player)
	else:
		clear {captcha::iloscZamkniec::%player%}
		kick player due to "&cZamknąłeś okno od Captcha 3 razy!"

Can't compare 'clicked item' with an item type (captcha.sk, line 16L if clicked item is lime wool named "&aKlknij mnie!";')

'else if' has to be placed just after another 'if' or 'else if' section (captcha.sk line 19: else if clicked item is red wool named "&cKliknij zielona wełne!":')

2 błedy

@Kormic

2 minuty temu, UnioNS napisał:

Can't compare 'clicked item' with an item type (captcha.sk, line 16L if clicked item is lime wool named "&aKlknij mnie!";')

'else if' has to be placed just after another 'if' or 'else if' section (captcha.sk line 19: else if clicked item is red wool named "&cKliknij zielona wełne!":')

2 błedy

@Kormic

Zedytowałem moją odpowiedź wyżej, przeczytaj ją jeszcze raz i sprawdź ponownie.

Jak ktos da ESC znaczy wyjdzie z tego okna (gui) to nie otwiera sie ponownie. Masz jakis pomysł? @Kormic

7 minut temu, UnioNS napisał:

Jak ktos da ESC znaczy wyjdzie z tego okna (gui) to nie otwiera sie ponownie. Masz jakis pomysł? @Kormic

Dziwne, u mnie skrypt działa bez zarzutu.

Zedytowałem jeszcze raz moją pierwszą odpowiedź, a dokładniej zawarty w niej skrypt (dodałem czyszczenie niepotrzebnych zmiennych).

Jeśli nadal nie zadziała, podaj silnik serwera, wersję silnika oraz wersję Skripta.

Wersja 1.16.1 i wszystko na ta wersje
Chciałbym abyś zmienił jak mozesz ze jak wyjdzie z  gui (ESC) to tez go wywala (mozliwe ze przez wersje cos nie chce dzialac)

Edit:

Albo inaczej jak gracz nie bedzie miał poprawnego captcha to po sekundzie znowu mu wlacza. (dopóki nie bedzie miał dobrze)

Edit:

Dobra mój błąd miałem opa (chociaz nie spodziewalem sie ze to cos zmieni)

Wszystko Działa!

6 minut temu, UnioNS napisał:

Wersja 1.16.1 i wszystko na ta wersje

To nie jedyne o co pytałem. Podaj również silnik serwera oraz wersję Skripta. Skripta sprawdzisz poprzez /ver Skript.

7 minut temu, UnioNS napisał:

Albo inaczej jak gracz nie bedzie miał poprawnego captcha to po sekundzie znowu mu wlacza. (dopóki nie bedzie miał dobrze)

Wolałbym zachować "higienę" wykonywania zleceń. Pamiętaj, zanim wyślesz na forum zlecenie, zastanów się co dokładnie ma zrobić w skrypcie zleceniobiorca. Teraz nie jest mi to na rękę, aby ci zmieniać skrypt, bo coś ci się zmieniło w wizji działania tego skryptu.

Ponieważ jesteś względnie nieaktywnym użytkownikiem, zrobię ten skrypt drugi raz, ale prosiłbym na przyszłość o pewność co do samego zlecenia.

Wpierw jednak odpowiedz na powyższe pytania, a będę mógł spokojnie zrobić skrypt.

Problem został rozwiązany.