Tpa

Masz na pewno mase takich skriptow na tym forum. Wystarczy troche poszukac.

Edit: Chociazby tutaj: 

xAffing ja szukam skryptu co jak sie ruszysz to anulujesz tpa 

33 minuty temu, ravcore_ napisał:

xAffing ja szukam skryptu co jak sie ruszysz to anulujesz tpa 

command /tpaccept:
    aliases: /tpyes
    trigger:
        send "{@prefix} &aGracz %player% &azaakceptowal prosbe o teleportacje!" to {tpa::%player%}
        send "{@prefix} &aZaakceptowales prosbe o teleportacje!"
        wait 10 seconds
            if {tpa::%player%} is set:
                teleport {tpa::%player%} to player
                clear {tpa::%player%}

on move:
    if {tpa::%player%} is set:
        clear {tpa::%player%}
        cancel event
 Nie testowalem, powinno dzialac, ustaw sobie tylko wiadomosci.

options:
	request_time: 30
	teleport_delay: 5
command /tpa [<text>]:
	trigger:
		if argument is not set:
			send "&cPoprawne użycie: /tpa <gracz>"
			stop
		set {_target} to argument parsed as player
		if {_target} is offline:
			send "&cBłąd: Nie ma takiego gracza."
			stop
		if {_target} is player:
			send "&cBłąd: Nie możesz teleportować się do siebie."
			stop
		if {tpa::request::%{_target}%::ignored::*} contains player:
			send "&c%{_target}% &7zablokował Ci możliwość wysyłania próśb o teleportację do niego."
			stop
		set {tpa::request::%{_target}%::received} to player
		set {tpa::request::%{_target}%::received::time} to now
		send "&7Wysłano prośbę o teleportację do &c%{_target}%&7."
		send "&c%player% &7chce się do Ciebie teleportować. Użyj &c/tpaccept&7, aby zaakceptować. Masz na to &c{@request_time} &7sekund." to {_target}
		stop
command /tpaccept:
	trigger:
		if {tpa::request::%player%::received} is not set:
			send "&cBłąd: Nie masz oczekującej prośby o teleportację."
			stop
		set {_target} to {tpa::request::%player%::received}
		if {_target} is offline:
			send "&cBłąd: Gracz opuścił serwer."
			clear {tpa::request::%player%::received}
			clear {tpa::request::%player%::received::time}
			stop
		if difference between {tpa::request::%player%::received::time} and now is more than {@request_time} seconds:
			clear {tpa::request::%player%::received}
			clear {tpa::request::%player%::received::time}
			send "&cBłąd: Prośba o teleportację przedawniona."
			stop
		clear {tpa::request::%player%::received}
		clear {tpa::request::%player%::received::time}
		send "&7Akceptowałeś prośbę o teleportowację."
		send "&c%player% &7akceptował Twoją prośbę o teleportację." to {_target}
		send "&7Teleportacja nastąpi za &c{@teleport_delay} &7sekund. &7Nie ruszaj się." to {_target}
		wait a second
		set {_tpos} to {_target}'s location
		loop {@teleport_delay}-1 times:
			if distance between {_tpos} and {_target} is more than 0.01:
				send "&cRuszyłeś się. Teleportacja przerwana." to {_target}
				stop
			if player is offline:
				send "&cGracz opuścił serwer. Teleportacja przerwana." to {_target}
				stop
			wait a second
		send "&7Teleportacja..." to {_target}
		teleport {_target} to player
		stop
command /tpdeny:
	trigger:
		if {tpa::request::%player%::received} is not set:
			send "&cBłąd: Nie masz oczekującej prośby o teleportację."
			stop
		set {_target} to {tpa::request::%player%::received}
		clear {tpa::request::%player%::received}
		clear {tpa::request::%player%::received::time}
		send "&7Odrzuciłeś prośbę o teleportowację."
		send "&c%player% &7odrzucił Twoją prośbę o teleportację." to {_target}
		stop
command /tpaignore [<text>]:
	trigger:
		if argument is not set:
			send "&cPoprawne użycie: /tpingore <gracz>"
			stop
		set {_target} to argument parsed as player
		if {_target} is offline:
			send "&cBłąd: Nie ma takiego gracza."
			stop
		if {_target} is player:
			send "&cBłąd: Nie możesz ignorować samego siebie."
			stop
		if {tpa::request::%player%::ignored::*} contains {_target}:
			send "&cBłąd: Ignorujesz już tego gracza."
			stop
		add {_target} to {tpa::request::%player%::ignored::*}
		send "&7Zablokowano &c%{_target}% &7możliwość wysyłania próśb o teleportację do Ciebie."
		send "&c%player% &7zablokował Ci możliwość wysyłania próśb o teleportację do niego." to {_target}
command /tpaunignore [<text>]:
	trigger:
		if argument is not set:
			send "&cPoprawne użycie: /tpuningore <gracz>"
			stop
		set {_target} to argument parsed as offline player
		if {tpa::request::%player%::ignored::*} doesn't contain {_target}:
			send "&cBłąd: Nie ignorujesz tego gracza."
			stop
		remove {_target} from {tpa::request::%player%::ignored::*}
		send "&7Odblokowano &c%{_target}% &7możliwość wysyłania próśb o teleportację do Ciebie."
		if {_target} is online:
			send "&c%player% &7odblokował Ci możliwość wysyłania próśb o teleportację do niego." to {_target}
		stop
command /tpaignored:
	trigger:
		if size of {tpa::request::%player%::ignored::*} is 0:
			send "&7Nikogo nie ignorujesz."
			stop
		set {_ignored} to "%{tpa::request::%player%::ignored::*}%"
		replace " and" with "," in {_ignored}
		send "&7Lista ignorowanych osób: &c%{_ignored}%"
		stop
command /tpahelp:
	trigger:
		send "&7Komendy TPA:"
		send "&c/tpa <gracz>"
		send "&c/tpaccept"
		send "&c/tpdeny"
		send "&c/tpaignore <gracz>"
		send "&c/tpaunignore <gracz>"
		send "&c/tpaignored"
		send "&c/tpahelp"