Problem z on chat

Zamiast robić zmienną do każdego etapu zrób jedną zmienną i w niej zapisuj aktualny etap.

Wczesniej wlasnie zrobiłem tak, że dodawało do jednej zmiennej 1, i było tak że np drugi etap aktywował się gdy ta zmienna wynosiła 2, ale było to samo ;/

Masz taki przykład, mam nadzieję, że Ci pomoże

command /ustaw:
	trigger:
		set {etap::%player%} to 1
		send "1.Podaj swoje imie na czacie"
		send "Aby anulowac, napisz anuluj"
		stop
on chat:
	if {etap::%player%} is set:
		cancel event
		if message is "anuluj":
			clear {etap::%player%}
			send "Anulowano"
			stop
		if {etap::%player%} is 1:
			set {imie::%player%} to message
			set {etap::%player%} to 2
			send "2.Podaj swoj nick"
			stop
		else if {etap::%player%} is 2:
			set {nick::%player%} to message
			set {etap::%player%} to 3
			send "2.Podaj swoj wiek"
			stop
		else if {etap::%player%} is 3:
			set {wiek::%player%} to message
			send "Zakonczono"
			clear {etap::%player%}
			send "1.Imie - %{imie::%player%}%"
			send "2.Nick - %{nick::%player%}%"
			send "3.Wiek - %{wiek::%player%}%"
			stop