wychodzenie poza granice mapy

W dniu 20.04.2026 o 19:25, robieserwer__13 napisał:

witam wszystkich potrzebuje pomocy robię serwer minecraft i nie wiem jak zablokować wychodzenie za border np perłami i zeby sie nie dalo podejsc do borderu i on odrzuca na 3-4 bloki 

Dziekuje z góry za pomoc

 

options:
    border-world: world
    border-margin: 4
    border-push: 1.35
    border-push-y: 0.35
    border-message: &cNie możesz podejść do granicy świata.

function nearBorder(l: location, margin: number) :: boolean:
    set {_border} to world border of world of {_l}
    set {_center} to world border center of {_border}
    set {_size} to world border size of {_border}
    set {_half} to {_size} / 2
    set {_x} to x-coordinate of {_l}
    set {_z} to z-coordinate of {_l}
    set {_cx} to x-coordinate of {_center}
    set {_cz} to z-coordinate of {_center}

    if {_x} >= {_cx} + {_half} - {_margin}:
        return true
    if {_x} <= {_cx} - {_half} + {_margin}:
        return true
    if {_z} >= {_cz} + {_half} - {_margin}:
        return true
    if {_z} <= {_cz} - {_half} + {_margin}:
        return true

    return false

function pushFromBorder(p: player):
    set {_l} to location of {_p}
    set {_border} to world border of world of {_l}
    set {_center} to world border center of {_border}
    set {_size} to world border size of {_border}
    set {_half} to {_size} / 2
    set {_x} to x-coordinate of {_l}
    set {_z} to z-coordinate of {_l}
    set {_cx} to x-coordinate of {_center}
    set {_cz} to z-coordinate of {_center}
    set {_vx} to 0
    set {_vz} to 0

    if {_x} >= {_cx} + {_half} - {@border-margin}:
        set {_vx} to -{@border-push}
    if {_x} <= {_cx} - {_half} + {@border-margin}:
        set {_vx} to {@border-push}
    if {_z} >= {_cz} + {_half} - {@border-margin}:
        set {_vz} to -{@border-push}
    if {_z} <= {_cz} - {_half} + {@border-margin}:
        set {_vz} to {@border-push}

    set velocity of {_p} to vector({_vx}, {@border-push-y}, {_vz})
    send action bar "{@border-message}" to {_p}

on player move:
    if world of player is world "{@border-world}":
        if nearBorder(location of player, {@border-margin}) is true:
            pushFromBorder(player)

on teleport:
    if event-entity is a player:
        if teleport cause is ender pearl:
            if world of event-entity is world "{@border-world}":
                if nearBorder(event-location, {@border-margin}) is true:
                    cancel event
                    pushFromBorder(event-entity)

łap, przetestowane

w options na samej górze tylko wpisz nazwe swojego świata gdzie ma to dzialac, domyslnie jest world