Problem z skriptem do komendy /autograf

Godzinę temu, SkriptNoob napisał:

Podstawowe informacje

• Wersja serwera: 1.20.1 paper
• Wersja Skript: 2.12.2

Opis zlecenia

Mam skript abym mógł podpisywać autografy lecz mi nie działa.

Problem: 

[Skript] Reloading the config, aliases and all scripts...
[19:23:26 INFO]: [Skript] Loaded 5172 aliases in 51ms
[19:23:26 INFO]: Line 12: (autograf.sk)
[19:23:26 INFO]:     List is missing 'and' or 'or', defaulting to 'and': "&7", "&7Autograf od:&r %player%", "&7"
[19:23:26 INFO]:     Line: set lore of player's tool to "&7", "&7Autograf od:&r %player%", "&7"
[19:23:26 INFO]:  
[19:23:26 INFO]: Line 14: (autograf.sk)
[19:23:26 INFO]:     a slot can't be set to 'player's tool with hidden enchantments' because the latter is neither an item type nor an item stack
[19:23:26 INFO]:     Line: set player's tool to player's tool with hidden enchantments
[19:23:26 INFO]:  
[19:23:26 INFO]: Line 19: (autograf.sk)
[19:23:26 INFO]:     This command doesn't have any arguments
[19:23:26 INFO]:     Line: if arg-1 is not set:
[19:23:26 INFO]:  
[19:23:26 INFO]: Line 23: (autograf.sk)
[19:23:26 INFO]:     This command doesn't have any arguments
[19:23:26 INFO]:     Line: set name of player's tool to colored arg-1
[19:23:26 INFO]:  
[19:23:26 INFO]: Line 24: (autograf.sk)
[19:23:26 INFO]:     List is missing 'and' or 'or', defaulting to 'and': "&7", "&7Autograf od:&r %player%", "&7"
[19:23:26 INFO]:     Line: set lore of player's tool to "&7", "&7Autograf od:&r %player%", "&7"
[19:23:26 INFO]:  
[19:23:26 INFO]: Line 26: (autograf.sk)
[19:23:26 INFO]:     a slot can't be set to 'player's tool with hidden enchantments' because the latter is neither an item type nor an item stack
[19:23:26 INFO]:     Line: set player's tool to player's tool with hidden enchantments
[19:23:26 INFO]:  
[19:23:26 INFO]:     Encountered 4 errors while reloading the config, aliases and all scripts! (118ms)

SKRIPT:

command /autograf:
    permission: autograf.command
    permission message: &cBrak permisji!
    trigger:
        if player's tool is air:
            send "&cMusisz trzymać coś w ręku!"
            stop

        # Domyślni gracze - stały autograf
        if player has permission "group.default":
            set name of player's tool to "&7Autograf"
            set lore of player's tool to "&7", "&7Autograf od:&r %player%", "&7"
            enchant player's tool with unbreaking 1
            set player's tool to player's tool with hidden enchantments
            send "&aUtworzono autograf!"
            stop

        # Pozostali - autograf z argumentu
        if arg-1 is not set:
            send "&cUżycie: /autograf <autograf>"
            stop

        set name of player's tool to colored arg-1
        set lore of player's tool to "&7", "&7Autograf od:&r %player%", "&7"
        enchant player's tool with unbreaking 1
        set player's tool to player's tool with hidden enchantments
        send "&aUtworzono autograf!"

 

Bardzo dziękuje za każdą odpowiedź i pomoc przy tym!

command /autograf [<text>]:
    permission: autograf.command
    permission message: &cBrak permisji!
    trigger:
        if player's tool is air:
            send "&cMusisz trzymać coś w ręku!" to player
            stop
        set {_item} to player's tool
        if player has permission "group.default":
            set name of {_item} to "&7Autograf"
            set lore of {_item} to "&7" and "&7Autograf od:&r %player%" and "&7"
            force {_item} to glint
            set player's tool to {_item}
            send "&aUtworzono autograf!" to player
            stop
        if arg-1 is not set:
            send "&cUżycie: /autograf <autograf>" to player
            stop
        set name of {_item} to colored arg-1
        set lore of {_item} to "&7" and "&7Autograf od:&r %player%" and "&7"
        force {_item} to glint
        set player's tool to {_item}
        send "&aUtworzono autograf!" to player

Cytat

• Wersja serwera: 1.20.1 paper
• Wersja Skript: 2.12.2

Ale zaktualizuj to lepiej bo ta wersja serwera boli.

Sam skript wspiera tylko 1.21 od wyzszych wersji