Antylogaut na Boss bara

options:
	combat_time: 20 seconds
	prefix: &7[&bCombat&7]

function combatTimer(p: player):
	if {-combat::%{_p}'s uuid%} is not set:
		set {-combat::%{_p}'s uuid%} to {@combat_time} from now
		set {_bar} to boss bar with id "CL_%{_p}%" with title "" with color purple with progress 100
		set bar style of {_bar} to segmented 20
		add {_p} to {_bar}
		while {-combat::%{_p}'s uuid%} is set:
			if {-combat::%{_p}'s uuid%} > now:
				set {_diff} to (seconds of (difference between {-combat::%{_p}'s uuid%} and now)) + 1
				set bar title of {_bar} to "{@prefix} &cJesteś podczas walki %{_diff}%s !"
				set bar progress of {_bar} to {_diff}*5
			else:
				delete {-combat::%{_p}'s uuid%}
				delete boss bar with id "CL_%{_p}%"
			wait 5 ticks
		send action bar "{@prefix} &aCzas walki się skończył!" to {_p}
	else:
		set {-combat::%{_p}'s uuid%} to {@combat_time} from now

function checkCombat(p: player) :: boolean:
	if {-combat::%{_p}'s uuid%} > now:
		return true
	else:
		delete {-combat::%{_p}'s uuid%}
		delete boss bar with id "CL_%{_p}%"
		return false

on damage of player:
	if attacker is a player:
		combatTimer(attacker)
		combatTimer(victim)
on join:
	delete {-combat::%player's uuid%}
	delete boss bar with id "CL_%player%"
on death:
	victim is a player
	delete {-combat::%victim's uuid%}
	delete boss bar with id "CL_%victim%"
on quit:
	if checkCombat(player) = true:
		kill player
		send "&c%player% zlogał podczas walki!" to all players
	delete {-combat::%player's uuid%}
	delete boss bar with id "CL_%player%"

zmodyfikuj pod siebie