dgXt8XWa
Język: Skript | Autor: Anonimowy

options:
    min-x: -10000
    max-x: 10000
    min-z: -10000
    max-z: 10000
    world: "world"
    snowmanDisplayName: "&f&lBałwan Boss"
    snowmanMaxHealth: 1000
    snowmanSpawnBroadcast: "&6Boss został zauważony na koordynatach X:&e%x-loc of last spawned snow golem%&6, Y: &e%y-loc of last spawned snow golem%&6, Z: &e%z-loc of last spawned snow golem%"
    snowmanCoordsBroadcast: "&6Boss znajduje się na koordynatach X:&e%x-loc of loop-entity%&6, Y: &e%y-loc of loop-entity%&6, Z: &e%z-loc of loop-entity%"
    
every 5 minutes:
    {snowmanBoss::alive} is not set
    set {_x} to random integer between {@min-x} and {@max-x}
    set {_z} to random integer between {@min-z} and {@max-z}
    spawn 1 snow golem at location at ({_x}, y-loc of highest block at location at ({_x}, 256, {_z}) in world {@world}, {_z}) in world {@world}
    set {snowmanBoss::alive} to true
    set display name of last spawned snow golem to {@snowmanDisplayName}
    set max health of last spawned snow golem to {@snowmanMaxHealth}
    heal last spawned snow golem
    broadcast {@snowmanSpawnBroadcast}

every 30 seconds:
    {snowmanBoss::alive} is set
    loop all snow golems:
        loop-entity's display name is {@snowmanDisplayName}
        broadcast {@snowmanCoordsBroadcast}
        
on damage of snow golem:
    display name of victim is {@snowmanDisplayName}
    damage cause is melting
    cancel event
    
on death of snow golem:
    display name of victim is {@snowmanDisplayName}
    clear {snowmanBoss::alive}
    attacker is set
    send title "&6%attacker% &azabił bossa!" to all players
    drop all diamond armor of protection 5 at event-location
    drop 1 diamond pickaxe of efficiency 6 and fortune 3 at event-location
    drop 64 tnt at event-location
    drop 64 emerald blocks at event-location
    drop 1 beacon at event-location