Q6mxVOFp
Język: Skript | Autor: Anonimowy

on damage:
    if attacker is player:
        if victim is player:
            if {antylogout::%victim%} is not set:
                send "&a&lSkill&f&lHC &7>> &cJestes podczas walki! Nie logaj!" to victim
            set {antylogout::%victim%} to 20
every 1 seconds:
    loop all players:
        if {antylogout::%loop-player%} is set:
            if {antylogout::%loop-player%} is greater than 0:
                remove 1 from {antylogout::%loop-player%}
                set action bar of loop-player to "&4&lAntyLogout &c&l(%{antylogout::%loop-player%}%)"
            else:
                clear {antylogout::%loop-player%}
                send "&a&lSkill&f&lHC &7>> &aSkonczyles walczyc." to loop-player
                set action bar of loop-player to "&2&lAntyLogout"
on quit:
    if {antylogout::%player%} is set:
        kill player
        broadcast "&a&lSkill&f&lHC &7>> &cGracz %player% wylogowal sie podczas walki!"
on death:
    clear {antylogout::%victim%}
on command:
    if {antylogout::%player%} is set:
        if command is not "helpop":
            cancel event
            send "&a&lSkill&f&lHC &7>> &4Uzywanie komend podczas pvp jest niemozliwe. Jedynie /helpop."
on rightclick on ender chest:
    if {antylogout::%player%} is set:
        cancel event
        send "&a&lSkill&f&lHC &7>> &cPodczas walki nie mozna otwierac enderchesta!"
on place:
    if player's y-coordinate is less than 30:
        if {antylogout::%player%} is set:
            cancel event
            send "&a&lSkill&f&lHC &7>> &cPodczas walki nie stawiac blokow ponizej 30 poziomu!"