5DDYWqa3
Język: Skript | Autor: stefanik11

options:
    zombie_drop: 10 glowstones;5 emeralds
    skeleton_horse_drop: 5 diamonds;6 gold ingots
    
command /halloweenboss [<text>]:
    trigger:
        if player doesn't has permission "rHalloween.spawnboss":
            send "&4Nie posiadasz do tego odpowiednich uprawnien!"
            stop
        spawn 1 adult zombie at player's location
        set {_zombie} to last spawned adult zombie
        
        spawn 1 skeleton horse at player's location
        set {_horse} to last spawned skeleton horse
        
        make {_zombie} ride {_horse}
        
        set {_horse}'s max health to 100
        heal {_horse}
        
        set {_zombie}'s display name to "&4Bezglowy jezdziec"
        set {_zombie}'s max health to 300
        heal {_zombie}
        
        set {_zombie}'s helmet to pumpkin
        set {_zombie}'s tool to diamond sword
        
        set metadata value "rHalloween" of {_zombie} to "true"
        set metadata value "rHalloween" of {_horse} to "true"
        
        send "&2Stworzyles bossa!"
        stop
        
on vehicle exit:
    if metadata "rHalloween" of event-entity isn't "true":
        stop
    cancel event
    stop
    
on death:
    if metadata "rHalloween" of victim isn't "true":
        stop
    if victim is zombie:
        loop ({@zombie_drop} split at ";"):
            drop (loop-value parsed as item) at victim's location
        stop
    if victim is skeleton horse:
        loop ({@skeleton_horse_drop} split at ";"):
            drop (loop-value parsed as item) at victim's location
        stop
    stop